如何从 ColdFusion 中的 CFC 返回小写 JSON？

Question

我有一个 ColdFusion 组件，它将返回一些 JSON 数据：

component
{
    remote function GetPeople() returnformat="json"
    {
        var people = entityLoad("Person");
        return people;
    }
}

不幸的是，返回的 JSON 的所有属性名称均为大写：

[
    {
        FIRSTNAME: "John",
        LASTNAME: "Doe"
    },
    {
        FIRSTNAME: "Jane",
        LASTNAME: "Dover
    }
]

有没有办法强制框架返回 JSON，以便属性名称全部为小写（也许是其他人编写的自定义 UDF/CFC）？

Answer 1

是的，不幸的是，这就是 ColdFusion 的工作方式。设置某些变量时，您可以强制使用小写，就像结构一样：

<cfset structName.varName = "test" />

将设置名称大写的变量。但是：

<cfset structName['varname'] = "test" />

将强制使用小写（或驼峰式，具体取决于您传入的内容）。

但是对于您正在做的 ORM 工作，我认为您无法对其进行任何控制。如果我错了，有人纠正我。

Answer 2

来自 http://livedocs.adobe.com/coldfusion /8/htmldocs/help.html?content=functions_s_03.html
注意：ColdFusion 在内部使用以下方式表示结构键名称
全大写字符，因此将键名称序列化为
全大写的 JSON 表示形式。任何处理 JSON 的 JavaScript
ColdFusion 结构的表示必须使用全大写
结构键名称，例如 CITY 或 STATE。您还可以使用
全大写名称 COLUMNS 和 DATA 作为两个数组的键
表示 JSON 格式的 ColdFusion 查询。

如果你自己定义变量，你可以使用方括号表示法（如 Jason 的答案所示），但对于像 ORM 这样的内置东西，我认为你被困住了 - 除非你想创建自己的结构，并克隆 ORM 版本手动将每个键变成小写，但这并不是一个很好的解决方案。 :/

Answer 3

这应该像你所描述的那样工作。

component
{
    remote function GetPeople() returnformat="json"
    {
        var people = entityLoad("Person");
        var rtn = [];
        for ( var i = 1; i <= arrayLen( people ); i++ ) {
            arrayAppend( rtn, {
                "firstname" = people[i].getFirstname(),
                "lastname" = people[i].getLastname()
            } );
        }
        return rtn;
    }
}

如果任何实体属性返回 null，则结构键将不存在。
要解决这个问题，请尝试这个

component
{
    remote function GetPeople() returnformat="json"
    {
        var people = entityLoad("Person");
        var rtn = [];
        for ( var i = 1; i <= arrayLen( people ); i++ ) {
            var i_person = {
                "firstname" = people[i].getFirstname(),
                "lastname" = people[i].getLastname()
            };
            if ( !structKeyExists( i_person, "firstname" ) ) {
                i_person["firstname"] = ""; // your default value
            }
            if ( !structKeyExists( i_person, "lastname" ) ) {
                i_person["lastname"] = ""; // your default value
            }
            arrayAppend( rtn, i_person );
        }
        return rtn;
    }
}