我怎样才能覆盖“地图”？ Grails 域类中的构造函数？

Question

创建域类的新实例时，我需要执行一些初始化。

class ActivationToken {
    String foo
    String bar
}

当我这样做时，我希望 bar 由 ActivationToken 内的代码初始化：

def tok = new ActivationToken(foo:'a')

我看不到如何“覆盖”“构造函数”来实现这一点。我知道在这种情况下我可以添加一个普通的构造函数，但这只是一个简单的例子。

Answer 1

地图构造函数来自 Groovy - 在本例中不是 Grails。我做了一些实验，这就是我想到的：

class Foo {
    String name = "bob"
    int num = 0

    public Foo() {
        this([:])
    }

    public Foo(Map map) {
        map?.each { k, v -> this[k] = v }
        name = name.toUpperCase()
    }

    public String toString() {
        "$name=$num"
    }
}

assert 'BOB=0' == new Foo().toString()
assert 'JOE=32' == new Foo(name:"joe", num: 32).toString()

基本上，如果您需要在构造后处理属性，则似乎必须手动重写构造函数。

或者，您可以覆盖各个设置器，这通常更干净、更安全：

class Foo {
    String name = "bob"
    int num = 0

    public void setName(n) {   
        name = n.toUpperCase()
    }

    public String toString() {
        "$name=$num"
    }
}

assert 'bob=0' == new Foo().toString()
assert 'JOE=32' == new Foo(name:"joe", num: 32).toString()

请注意，默认值不会被处理，但在大多数情况下应该没问题。

Answer 2

上述解决方案也适用于从 Web 请求中的参数初始化对象的情况，例如，您希望忽略无关值、捕获 Missing property 异常。

public Foo(Map map) {
    try {
        map?.each { k, v -> this[k] = v }
    }
    catch(Exception e){
    }
}