如何保存和加载我的 svTree 数据结构？

Question

我正在尝试使用 VirtualStringTree 组件实现一个简单的联系人管理器。我将其设置为看起来像一个列表视图组件，只有三列，全部包含文本：

对于数据结构，我正在使用 Linas 的 svTree，这在另一个 Stack Overflow 问题中提到过。

我已经声明了这样的记录：

type
  TMainData = record
    Name, Email, Password: string;
  end;

在表单的 OnCreate 中，我有这样的：

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyTree := TSVTree<TMainData>.Create(False);
  MyTree.VirtualTree := vst1;
end;

我正在添加来自 TEdits 的数据，如下所示：

procedure TForm1.BuildStructure;
var
  svNode: TSVTreeNode<TMainData>;
  Data: TMainData;
begin
  MyTree.BeginUpdate;
  try
    Data.Name := edtname.Text;
    Data.Email := edtEmail.Text;
    Data.Password := edtPassword.Text;
    svNode := MyTree.AddChild(nil, Data);
  finally
    MyTree.EndUpdate;
  end;
  Label1.Caption := 'Count: '+IntToStr(MyTree.TotalCount);
end;

如何将其保存到要加载回的流或文件中？我尝试过使用 MyTree.SaveToFile('C:/Test.dat') 和 MyTree.LoadFromFile('C:/Test.dat')，但是当它加载时后面的树视图不包含任何数据，只有一个空白行。

Answer 1

您需要为您的 TSVTree 设置 OnLoadNode 和 OnSaveNode 过程并在此处实现您的逻辑。您可以查看 Demos 文件夹中的 Project2。例如：

uses
  uSvHelpers;

MyTree.OnSaveNode := DoSave;
MyTree.OnLoadNode := DoLoad;

procedure TForm1.DoLoad(Sender: TSVTree<TMainData>; Node: TSVTreeNode<TMainData>; Stream: TStream);
var
  obj: TMainData;
begin
  //
  if Assigned(Node) then
  begin
    //read from stream
    //read in correct order
    obj.Name := Stream.AsString;
    obj.Email := Stream.AsString;
    obj.Password := Stream.AsString;
    Node.FValue := obj;
  end;
end;

procedure TForm1.DoSave(Sender: TSVTree<TMainData>; Node: TSVTreeNode<TMainData>; Stream: TStream);
begin
  if Assigned(Node) then
  begin
    //read from stream
    Stream.WriteString(Node.FValue.Name);
    Stream.WriteString(Node.FValue.Email);
    Stream.WriteString(Node.FValue.Password);
  end;
end;

之后您只需调用 MyTree.SaveToFile('C:/Test.dat') 或 MyTree.LoadFromFile('C:/Test.dat') 即可。在我的演示和本示例中，我使用了另一个单元 (uSvHelpers)，它实现了 TStream 助手以提供更多 OO 流支持。您当然可以使用自己的方式将数据信息写入流。

Answer 2

看起来您需要实现 OnSaveNode 和 OnLoadNode 事件：

procedure TForm.VTLoadNode(Sender: TBaseVirtualTree;
  Node: PVirtualNode; Stream: TStream);
begin
  // Load Node Data record from the stream
end;

procedure TForm.VTSaveNode(Sender: TBaseVirtualTree;
  Node: PVirtualNode; Stream: TStream);
begin
  // Save Node Data record to the stream
end;