清理 Clojure 函数

Question

来自命令式编程语言，我正在尝试了解 Clojure，希望利用它的多线程功能。
4Clojure 的问题之一是编写一个函数，生成长度为 N 的斐波那契数列表，对于 N > 1. 我编写了一个函数，但鉴于我的背景有限，我想了解一下这是否是最好的 Clojure 处理方式。代码如下：

(fn fib [x] (cond 
               (= x 2) '(1 1)
            :else   (reverse (conj (reverse (fib (dec x))) (+ (last (fib (dec x))) (-> (fib (dec x)) reverse rest first))))
          ))

Answer 1

最惯用的“功能”方法可能是创建一个无限惰性的斐波那契数序列，然后提取前 n 个值，即：

(take n some-infinite-fibonacci-sequence)

以下链接有一些非常有趣的方法来沿着这些线生成斐波那契数列：

http://en.wikibooks.org/wiki/Clojure_Programming/Examples/Lazy_Fibonacci

最后，这是另一个值得考虑的有趣实现：

 (defn fib [n]
   (let [next-fib-pair (fn [[a b]] [b (+ a b)])
         fib-pairs (iterate next-fib-pair [1 1])
         all-fibs (map first fib-pairs)]
     (take n all-fibs)))


 (fib 6)
 => (1 1 2 3 5 8)

它并不那么简洁，但很好地演示了使用 Clojure 的解构、惰性序列和高阶函数来解决该问题。

Answer 2

这是我非常喜欢的斐波那契版本（我从 clojure wikibook 中获取了实现：http:// en.wikibooks.org/wiki/Clojure_Programming）

 (def fib-seq (lazy-cat [0 1] (map + (rest fib-seq) fib-seq)))

它的工作原理如下：假设您已经拥有无限的斐波那契数列。如果您取出序列的尾部并将其按元素添加到原始序列中，您将得到斐波那契序列（尾部的尾部），

0 1 1 2 3 5 8 ...
1 1 2 3 5 8 ...
-----------------
1 2 3 5 8 13 ... 

因此您可以使用它来计算序列。您需要两个初始元素 [0 1]（或 [1 1]，具体取决于您开始序列的位置），然后只需映射添加元素的两个序列即可。请注意，这里需要惰性序列。

我认为这是最优雅且（至少对我来说）最令人费解的实现。

编辑：fib 函数是

 (defn fib [n] (nth fib-seq n)) 

Answer 3

这是一种可以让您接触到惰性序列的方法，尽管它肯定不是计算斐波那契序列的最佳方法。

给出斐波那契数列的定义，我们可以看到它是通过将相同的规则重复应用于 '(1 1) 的基本情况而构建的。 Clojure 函数 iterate 听起来很适合这个：

user> (doc iterate)
-------------------------
clojure.core/iterate
([f x])
  Returns a lazy sequence of x, (f x), (f (f x)) etc. f must be free of side-effects

因此，对于我们的函数，我们需要一些东西来获取我们到目前为止计算的值，对最近的两个值求和，然后返回一个列表新值和所有旧值。

(fn [[x y & _ :as all]] (cons (+ x y) all))

这里的参数列表仅意味着 x 和 y 将绑定到作为函数参数传递的列表中的前两个值，该列表包含前两个值之后的所有参数将绑定到 _，并且可以通过 all 引用作为参数传递给函数的原始列表。

现在，迭代将返回中间值的无限序列，因此对于我们的情况，我们希望将其包装在仅返回我们感兴趣的值的内容中；惰性求值将停止整个无限序列的求值。

(defn fib [n]
   (nth (iterate (fn [[x y & _ :as all]] (cons (+ x y) all)) '(1 1)) (- n 2)))

另请注意，这会以与您的实现相反的顺序返回结果；当然，用 reverse 解决这个问题很简单。

编辑：或者实际上，正如 amalloy 所说，通过使用向量：

(defn fib [n]
   (nth (iterate (fn [all]
                   (conj all (->> all (take-last 2) (apply +)))) [1 1])
        (- n 2)))

Answer 4

请参阅 Stu Halloway 编写的Clojure 编程中的 Christophe Grand 斐波那契解决方案。这是我见过的最优雅的解决方案。

(defn fibo [] (map first (iterate (fn [[a b]] [b (+ a b)]) [0 1])))
(take 10 (fibo))

另请参阅

如何使用生成斐波那契序列Clojure？