如何检查哪个 Office 应用程序 VBA 代码正在运行？

Question

我目前正在使用 VBA 代码，该代码最初用于 Excel 文档。我可以只零售或在 Word 中使用的代码，但我认为扩展该应用程序可能会更好，以便它“可能”兼容任何 MS Office 应用程序。但我不完全确定该怎么做。

例如，基于 Excel 的代码获取文档的路径：

If libDir = "" Then libDir = ThisWorkbook.Path

要将其扩展到 Word，我只需将 ThisWorkbook 替换为 ActiveDocument。

但是否有可能找出哪个 Office 应用程序正在运行 VBA 代码，以便我可以保留两者。

 'IF VBA run from Word Then
     If libDir = "" Then libDir = ThisWorkbook.Path
 'ELSE VBA run from Excel then
     If libDir = "" Then libDir = ActiveDocument.path
 'End If

到目前为止，我可以看到我可以找出 word 或 excel 是否打开，但我不能假设因为它是打开的，所以它正在运行该特定模块。但这超出了我的 VBA 知识范围。

我也尝试过这个 currentproject.path 但这不起作用。

提前致谢

Answer 1

我自己发现了这种需要，并努力寻找任何类型的条件编译或其他方法来区分应用程序。

刚才，我凭直觉发现每个办公应用程序中的 Application 对象都有 .Name 和 .Version String 属性。

因此，您可以执行一些类似这样的代码来确定您正在运行哪个应用程序：

Private Sub TestApplication()
  Select Case Application.Name
    Case "Microsoft Word"
      MsgBox "Running in Word " + Application.Version
    Case "Microsoft Excel"
        MsgBox "Running in Excel " + Application.Version
    Case "Microsoft PowerPoint"
        MsgBox "Running in PowerPoint " + Application.Version
    Case "Microsoft Visio"
        MsgBox "Running in Visio " + Application.Version
    Case "Microsoft Access"
        MsgBox "Running in Access " + Application.Version
    Case "Outlook"
        MsgBox "Running in Outlook " + Application.Version
    Case Else
       MsgBox "Unknown Application " + Application.Name + " " + Application.Version
  End Select
End Sub

Answer 2

如果总体意图是构建和重用可在所有 Office 应用程序中使用的 VBA 代码库，更好的方法可能是使用条件编译。上面 TestApplication 示例中的前两种情况将如下所示：（

Private Sub TestApplication()
    #If Word then
        MsgBox "Running in Word " + Application.Version
    #ElseIf Excel 
        MsgBox "Running in Excel " + Application.Version
    #Else
        MsgBox "Running in SomeOtherApplication " + Application.Version
    #End if    Case "Microsoft PowerPoint"
End Sub

所有其他应用程序均已使用 #Else 捕获。）

通过在包含以下内容的 VBProject 的属性中适当设置条件编译参数“Word”和“Excel”重用代码就可以确保只编译该实现所需的代码。例如，在 Word 中使用所需的条件编译参数为：

---

Word = -1 : Excel = 0

---

即 Word = True : Excel = False 是将代码编译到 Word 特定应用程序所需的设置。

最后一个一般提示：
设置条件编译参数的值时，始终使用 -1 表示 True。如果您稍后决定反转语句的意图，则可以通过添加 NOT 轻松更改意图。这是一个好主意，因为：

您可能知道，VBA 条件语句将条件语句中的非零值视为 true。例如，这将转到标签第 10 行：
如果 5 则转到 LINE10
这是可以的，直到您尝试更改此类语句的意图以不根据此类条件执行某些操作。该语句仍会转到第 10 行。
如果不是 5，则转到 LINE10
NOT 运算符不会将 -1 以外的任何数字解析为 False（即 0）。

Answer 3

尝试改进代码以适应各种 Office 应用程序听起来确实很复杂。如果这段代码可以应用在word和excel中，那么它会做什么 - 也许是vbscript，然后自动化你想要使用的对象是一个选项

在上面的具体示例中，它实际上可以编译好（我已经在xl2003中进行了测试， xl2010 和 word2010），因此通过错误处理，代码将运行并跳过其他有问题的区域。

 On Error Resume Next
    If libDir = "" Then libDir = ThisWorkbook.Path
    If libDir = "" Then libDir = ActiveDocument.Path
 On Error GoTo 0

还有一点需要考虑，如果文件未保存，路径将不存在。