OpenGL：调试“单通道线框渲染”

Question

我正在尝试实现论文“单通道线框渲染”，它看起来很简单，但它给了我所期望的厚暗值。

论文没有给出计算海拔高度的确切代码，所以我按照自己认为合适的方式进行了操作。代码应该将三个顶点投影到视口空间中，获取它们的“高度”并将它们发送到片段着色器。

片段着色器确定最近边缘的距离并生成边缘强度。我不确定我应该如何处理这个值，但由于它应该在 [0,1] 之间缩放，所以我将其与输出颜色的倒数相乘，但它非常弱。

我有几个问题，我不确定这些问题是否在论文中得到解决。首先，高度应该以 2D 而不是 3D 的形式计算？其次，他们提供 DirectX 功能，其中 DirectX 具有不同的视口空间 z 范围，对吗？这有关系吗？我将传出高度距离预乘以视口空间坐标的 w 值，因为他们建议纠正透视投影。

尝试校正透视投影的图像

没有校正（不预乘 w 值）

未校正的图像似乎有明显的问题，没有校正更远的侧面的透视，但是经过透视校正的人的价值观非常弱。

任何人都可以看到我的代码有什么问题或者如何从这里调试它吗？

我在 GLSL 中的顶点代码...

float altitude(in vec3 a, in vec3 b, in vec3 c) { // for an ABC triangle
  vec3 ba = a - b;
  vec3 bc = c - b;
  vec3 ba_onto_bc = dot(ba,bc) * bc;
  return(length(ba - ba_onto_bc));
}

in vec3 vertex; // incoming vertex
in vec3 v2; // first neighbor (CCW)
in vec3 v3; // second neighbor (CCW)
in vec4 color;
in vec3 normal;
varying vec3 worldPos;
varying vec3 worldNormal;
varying vec3 altitudes;
uniform mat4 objToWorld;
uniform mat4 cameraPV;
uniform mat4 normalToWorld;
void main() {
  worldPos = (objToWorld * vec4(vertex,1.0)).xyz;
  worldNormal = (normalToWorld * vec4(normal,1.0)).xyz;
  //worldNormal = normal;
  gl_Position = cameraPV * objToWorld * vec4(vertex,1.0);
  // also put the neighboring polygons in viewport space
  vec4 vv1 = gl_Position;
  vec4 vv2 = cameraPV * objToWorld * vec4(v2,1.0);
  vec4 vv3 = cameraPV * objToWorld * vec4(v3,1.0);
  altitudes = vec3(vv1.w * altitude(vv1.xyz,vv2.xyz,vv3.xyz),
                   vv2.w * altitude(vv2.xyz,vv3.xyz,vv1.xyz),
                   vv3.w * altitude(vv3.xyz,vv1.xyz,vv2.xyz));
  gl_FrontColor = color;
}

和我的片段代码...

varying vec3 worldPos;
varying vec3 worldNormal;
varying vec3 altitudes;
uniform vec3 cameraPos;
uniform vec3 lightDir;
uniform vec4 singleColor;
uniform float isSingleColor;
void main() {
    // determine frag distance to closest edge
    float d = min(min(altitudes.x, altitudes.y), altitudes.z);
    float edgeIntensity = exp2(-2.0*d*d);
    vec3 L = lightDir;
    vec3 V = normalize(cameraPos - worldPos);
    vec3 N = normalize(worldNormal);
    vec3 H = normalize(L+V);
    //vec4 color = singleColor;
    vec4 color = isSingleColor*singleColor + (1.0-isSingleColor)*gl_Color;
    //vec4 color = gl_Color;
    float amb = 0.6;
    vec4 ambient = color * amb;
    vec4 diffuse = color * (1.0 - amb) * max(dot(L, N), 0.0);
    vec4 specular = vec4(0.0);
    gl_FragColor = (edgeIntensity * vec4(0.0)) + ((1.0-edgeIntensity) * vec4(ambient + diffuse + specular));
}

Answer 1

我已经实现了猪的想法，结果很完美，这是我的截图：

struct MYBUFFEREDVERTEX {
    float x, y, z;
    float nx, ny, nz;
    float u, v;
    float bx, by, bz;
};

const MYBUFFEREDVERTEX g_vertex_buffer_data[] = {
    -1.0f, -1.0f, 0.0f,
    0.0f, 0.0f, 1.0f,
    0.0f, 0.0f,
    1.0f, 0.0f, 0.0f,

    1.0f, -1.0f, 0.0f,
    0.0f, 0.0f, 1.0f,
    1.0f, 0.0f,
    0.0f, 1.0f, 0.0f,

    -1.0f, 1.0f, 0.0f,
    0.0f, 0.0f, 1.0f,
    0.0f, 1.0f,
    0.0f, 0.0f, 1.0f,

    1.0f, 1.0f, 0.0f,
    0.0f, 0.0f, 1.0f,
    1.0f, 1.0f,
    1.0f, 0.0f, 0.0f,
};

glDrawArrays(GL_TRIANGLE_STRIP, 0, 4);

顶点着色器：

#ifdef GL_ES
// Set default precision to medium
precision mediump int;
precision mediump float;
#endif

uniform mat4 u_mvp_matrix;
uniform vec3 u_light_direction;

attribute vec3 a_position;
attribute vec3 a_normal;
attribute vec2 a_texcoord;
attribute vec3 a_barycentric;

varying vec2 v_texcoord;
varying float v_light_intensity;
varying vec3 v_barycentric;

void main()
{
    // Calculate vertex position in screen space
    gl_Position = u_mvp_matrix * vec4(a_position, 1.0);
    // calculate light intensity, range of 0.3 ~ 1.0
    v_light_intensity = max(dot(u_light_direction, a_normal), 0.3);
    // Pass texture coordinate to fragment shader
    v_texcoord = a_texcoord;
    // Pass bary centric to fragment shader
    v_barycentric = a_barycentric;
}

片段着色器：

#ifdef GL_ES
// Set default precision to medium
precision mediump int;
precision mediump float;
#endif

uniform sampler2D u_texture;

varying vec2 v_texcoord;
varying float v_light_intensity;
varying vec3 v_barycentric;

void main()
{
    float min_dist = min(min(v_barycentric.x, v_barycentric.y), v_barycentric.z);
    float edgeIntensity = 1.0 - step(0.005, min_dist);
    // Set diffuse color from texture
    vec4 diffuse = texture2D(u_texture, v_texcoord) * vec4(vec3(v_light_intensity), 1.0);
    gl_FragColor = edgeIntensity * vec4(0.0, 1.0, 1.0, 1.0) + (1.0 - edgeIntensity) * diffuse;
}

Answer 2

首先，你的函数altitude()有缺陷，ba_onto_bc计算错误，因为bc不是单位长度（要么标准化bc，要么将ba_onto_bc除以长度平方的点（bc，bc） - 你可以节省计算平方根）。

如果您想要恒定厚度的边缘，则应以 2D 计算高度；如果您想要透视正确的边缘，则应以 3D 计算高度。

使用重心坐标作为单独的顶点属性会容易得多（即三角形的顶点 0 将得到 (1 0 0)、第二个顶点 (0 1 0) 和最后一个顶点 (0 0 1)）。在片段着色器中，您将计算最小值并使用step()或smoothstep()来计算边缘度。

这将只需要 1 个属性而不是当前的两个属性，并且它还可以消除在顶点着色器中计算高度的需要（尽管如果您想预先缩放重心坐标以便获得均匀的粗线，它可能会很有用 - 但可以离线计算） ）。它还应该几乎可以立即工作，因此这将是实现所需行为的良好起点。