Moose - 导入的函数不算作角色方法？

Question

我有一个角色声明它需要一个方法（使用 requires）。 我试图通过直接在类的符号表中定义该方法来安装该方法。 然而，在某些情况下它有效，而在其他情况下则无效。

在下面，WORKS 意味着没有报告错误，DOESN'T WORK 意味着我收到错误：'arole' 要求方法 'finddepth' 由 'aclass' 实现

package arole;

use Moose::Role;

requires 'finddepth';

package anexporter;

sub import {
  no strict 'refs';
  *{ "aclass::finddepth" } = sub {};
}

package anexporter2;
sub import {
  eval "sub aclass::finddepth {}";
}

package aclass;

use Moose;

# WORKS:
# sub finddepth { }

# WORKS:
# BEGIN { *{finddepth} = sub {} };

# DOESN'T WORK:
# use File::Find qw(finddepth);

# DOESN'T WORK:
# BEGIN { anexporter->import };

# WORKS:
# BEGIN { no strict 'refs'; *{ "aclass::finddepth" } = sub { }};

# WORKS:
# BEGIN { anexporter2->import };

with 'arole';

1;

Answer 1

这里的问题是，Moose 非常努力地跟踪方法的来源，以便本地包中未定义的任何内容都不会意外地被视为方法。

如果您不使用原始 glob，而是使用 Moose 元协议来注入导入，那么这会起作用，因为 Moose 会知道您正在尝试显式添加方法。

package anexporter {

    sub import {
        aclass->meta->add_method(finddepth => sub {})
    }

}

然而，这确实意味着 CPAN 上的任何内容（例如 File::Find 的 finddepth）都需要包装。由于通常导出不希望被调用为方法，因此可能无论如何都需要发生。

Answer 2

你的角色是寻找一个名为 findDepth 的方法；简单地从其他包导入它并不是一个方法。我将其包装在一个方法中，因为您的角色方法无论如何都需要调用 finddepth 作为方法，才能正确解决所有问题。

# in package aclass
use File::Find;

sub finddepth { shift; File::Find::finddepth(@_) }

这有几个优点：并不奇怪，也不神奇，而且一切都按预期进行。