使用 sed 复制行并从重复项中删除字符

Question

我有一个如下所示的文件：

@"Afghanistan.png",
@"Albania.png",
@"Algeria.png",
@"American_Samoa.png",

我希望它看起来像这样

@"Afghanistan.png",
@"Afghanistan",
@"Albania.png",
@"Albania",
@"Algeria.png",
@"Algeria",
@"American_Samoa.png",
@"American_Samoa",

我想我可以使用 sed 来执行此操作，但我不知道如何在缓冲区中存储某些内容然后修改它。

我是否使用了正确的工具？

谢谢

Answer 1

您不必对正则表达式和替换字符串感到棘手：使用 sed 的 p 命令完整打印该行，然后修改该行并让它隐式打印

sed 'p; s/\.png//'

Answer 2

Glenn jackman 的响应是好的，但它也将与表达式不匹配的行加倍。

相反，这个仅将与表达式匹配的行加倍：

sed -n 'p; s/\.png//p'

这里，-n 代表“除非明确打印，否则不打印任何内容”，s/\.png//p 中的 p 强制打印如果替换已完成，但不强制替换

Answer 3

使用 sed 可以很容易地做到这一点，您甚至不需要使用保留空间（sed 辅助缓冲区）。给定下面的input 文件：

$ cat input 
@"Afghanistan.png",
@"Albania.png",
@"Algeria.png",
@"American_Samoa.png",

您应该使用此命令：

sed 's/@"\([^.]*\)\.png",/&\
@"\1",/' input 

结果：

$ sed 's/@"\([^.]*\)\.png",/&\
@"\1",/' input 
@"Afghanistan.png",
@"Afghanistan",
@"Albania.png",
@"Albania",
@"Algeria.png",
@"Algeria",
@"American_Samoa.png",
@"American_Samoa",

此命令只是一个替换命令 (s///)。它匹配以 @" 开头、后跟非句点字符 ([^.]*) 和 .png", 的任何内容。此外，它使用组括号 \( 和 \) 匹配 .png", 之前的所有非句点字符，因此我们可以得到什么因此，这是要替换的正则表达式：

@"\([^.]*\)\.png",

So 跟在命令的替换部分之后 & 命令仅插入与 匹配的所有内容。更改内容中的 @"\([^.]*\)\.png", 如果它是替换部分的唯一元素，则输出中不会发生任何更改。 & 有一个换行符 - 由反斜杠 \ 表示，后跟一个实际的换行符 - 在新行中我们添加 @" 字符串后跟第一组的内容(\1)，然后是字符串 ",。

这只是该命令的简要说明。希望这会有所帮助。另外，请注意，您可以使用 \n 字符串在某些版本的 sed（例如 GNU sed）中表示换行符，它会呈现更简洁和可读的命令：

sed 's/@"\([^.]*\)\.png",/&\n@"\1",/' input 

Answer 4

与卡尔斯·萨拉和格伦·杰克曼相比，我更喜欢这个：

sed '/.png/p;s/.png//'

只能说这是个人喜好。

Answer 5

或者可以组合两个版本并仅在与所需模式匹配的行上应用复制

sed -e '/^@".*\.png",/{p;s/\.png//;}' input