ANTLR 语法不处理我的“不”正确操作

Question

我正在尝试解析一种小型表达式语言（我没有从供应商处定义该语言），一切都很好，直到我尝试使用 not 运算符，该运算符是该语言中的波浪号。

我的语法深受这两个链接（又名无耻剪切和粘贴）的影响：

http:// /www.codeproject.com/KB/recipes/sota_expression_evaluator.aspx http://www.alittlemadness.com/2006 /06/05/antlr-by-example-part-1-the-language

该语言由三种表达式类型组成，可以与 and、or、not 运算符和括号一起使用来更改优先级。表达式为：

Skill("name") > some_number (can also be <, >=, <=,  =, !=)
SkillExists("name")
LoggedIn("name") (this one can also have name@name)

此输入工作正常：

Skill("somename") > 1 | (LoggedIn("somename") & SkillExists("othername"))

但是，一旦我尝试使用 not 运算符，我就会得到 NoViableAltException。我不明白为什么。我将我的语法与 codeproject.com 链接上的 ECalc.g 语法进行了比较，它们似乎匹配，一定存在一些我看不到的细微差别。失败：

Skill("somename") < 10 ~ SkillExists("othername")

我的语法：

grammar UserAttribute;

options {
output=AST;
ASTLabelType=CommonTree;
}

tokens {
SKILL = 'Skill' ;
SKILL_EXISTS = 'SkillExists' ;
LOGGED_IN = 'LoggedIn';
GT = '>';
LT = '<';
LTE = '<=';
GTE = '>=';
EQUALS = '=';
NOT_EQUALS = '!=';  
AND = '&';
OR = '|' ;
NOT = '~';
LPAREN   = '(';
RPAREN = ')';
QUOTE = '"';
AT = '@';       
}

/*------------------------------------------------------------------
 * PARSER RULES
 *------------------------------------------------------------------*/  
expression : orexpression EOF!; 
orexpression    : andexpression (OR^ andexpression)*;
andexpression   : notexpression (AND^ notexpression)*;  
notexpression : primaryexpression | NOT^ primaryexpression;
primaryexpression : term | LPAREN! orexpression RPAREN!;
term    : skill_exists | skill | logged_in;
skill_exists    : SKILL_EXISTS LPAREN QUOTE NAME QUOTE RPAREN;
logged_in : LOGGED_IN LPAREN QUOTE NAME (AT NAME)? QUOTE RPAREN;
skill:  SKILL LPAREN QUOTE NAME QUOTE RPAREN ((GT | LT| LTE | GTE | EQUALS | NOT_EQUALS)? NUMBER*)?;

/*------------------------------------------------------------------
 * LEXER RULES
 *------------------------------------------------------------------*/
NAME    : ('a'..'z' | 'A'..'Z' | '_')+;
NUMBER  : ('0'..'9')+ ;
WHITESPACE : ( '\t' | ' ' | '\r' | '\n'| '\u000C' )+    { $channel = HIDDEN; } ;

Answer 1

我有两点备注：

1

由于您正在解析单个表达式（expression : orexpression EOF!;），因此输入 "Skill("somename") < 10 ~ SkillExists("othername" )" 不仅在您的语法中无效，而且在任何表达式解析器（我知道）方面也是无效的。 notexpression 仅采用“右侧”表达式，因此 ~ SkillExists("othername") 是单个表达式，而 Skill("somename") < 10 也是单个表达式。但在这两个单个表达式之间，没有 OR 或 AND 运算符。这与评估表达式 true false 而不是 true | 是一样的。 false 或 true 和 false。

简而言之，你的语法不允许：

Skill("somename") < 10 ~ SkillExists("othername")

但允许：

Skill("somename") < 10 & SkillExists("othername")

这对我来说似乎是合乎逻辑的。

2

我不太明白你的 skill 规则（顺便说一句，这是不明确的）：

skill
 : SKILL LPAREN QUOTE NAME QUOTE RPAREN 
     ((GT | LT| LTE | GTE | EQUALS | NOT_EQUALS)? NUMBER*)?
 ;

这意味着运算符是可选的，并且末尾可以有零个或多个数字。这意味着以下输入均有效：

• Skill("foo") = 10 20
• Skill("foo") 10 20 30
• Skill("foo" ) <

也许您的意思是：

skill
 : SKILL LPAREN QUOTE NAME QUOTE RPAREN 
     ((GT | LT| LTE | GTE | EQUALS | NOT_EQUALS)^ NUMBER)?
 ;

相反？ （? 变为 ^ 并且 * 被删除）

如果我只更改该规则并解析输入：

Skill("somename") < 10 & SkillExists("othername")

将创建以下 AST：

（如您所见，AST 需要更好地形成：即您需要一些重写规则在你的skill_exists、logged_in 和 skill 规则）

---

编辑

，如果您希望连续的表达式具有隐含的 AND之间的标记，执行如下操作：

grammar UserAttribute;

...
tokens {
...
I_AND;     // <- added a token without any text (imaginary token)
AND = '&';
...
}

andexpression
  :  (notexpression -> notexpression) (AND? notexpression -> ^(I_AND $andexpression notexpression))*
  ;  

...

如您所见，由于 AND 现在是可选的，因此不能在重写规则中使用它，但您必须使用虚构的标记 I_AND。

如果您现在解析输入：

Skill("somename") < 10 ~ SkillExists("othername")

您将得到以下 AST：