在 Mathematica 中应用特定级别的欧氏距离

Question

请考虑：

daList = {{{21, 18}, {20, 18}, {18, 17}, {20, 15}}, 
          {{21, 18}, {20, 18}, {21, 14}, {21, 14}}};

我想计算该列表的 2 个子列表中每个点之间的距离：

但是我需要使用 Function 来应用在正确的级别：

Function[seqNo, 
         EuclideanDistance[#, {0, 0}] & /@ daList[[seqNo]]] /@ 
         Range[Length@daList]

out = {{3 Sqrt[85], 2 Sqrt[181], Sqrt[613], 25}, {3 Sqrt[85], 2 Sqrt[181], 
        7 Sqrt[13], 7 Sqrt[13]}}

有没有办法避免这个重功能有吗？ 要指定级别避免使用 seqNo 作为参数的函数？ ：

EuclideanDistance[#, {0, 0}] & /@ daList

out={EuclideanDistance[{{21, 18}, {20, 18}, {18, 17}, {20, 15}}, {0, 0}], 
     EuclideanDistance[{{21, 18}, {20, 18}, {21, 14}, {21, 14}}, {0, 0}]}

Answer 1

您是否尝试过 Map 中的 Level 规范？

Map[EuclideanDistance[#, {0, 0}] &, daList, {2}]

给出

{{3 Sqrt[85],2 Sqrt[181],Sqrt[613],25},{3 Sqrt[85],2 Sqrt[181],7 Sqrt[13],7 Sqrt[13]}}

Answer 2

为了补充@Markus的答案：如果你的 daList 非常大并且是数值型的，下面的方法会快得多（比如 30x），尽管不太通用：

Sqrt@Total[daList^2,{3}]

这是一个例子：

In[17]:= largeDaList = N@RandomInteger[30,{100000,4,2}];
In[18]:= Map[EuclideanDistance[#,{0,0}]&,largeDaList,{2}]//Short//Timing
Out[18]= {0.953,{{31.7648,34.6699,20.3961,31.305},<<99998>>,{<<18>>,<<2>>,0.}}}

In[19]:= Sqrt@Total[largeDaList^2,{3}]//Short//Timing
Out[19]= {0.031,{{31.7648,34.6699,20.3961,31.305},<<99998>>,{<<18>>,<<2>>,0.}}}

原因是函数就像Power和Sqrt是Listable一样，您将迭代推入内核。像 Map 这样的函数在很多情况下也可以自动编译映射函数，但在这种情况下显然不行。

编辑

根据OP的要求，这里是对非平凡参考点情况的概括：

refPoint = {3, 5};
Sqrt@Total[#^2, {3}] &@Transpose[Transpose[daList, {3, 2, 1}] - refPoint, {3, 2, 1}]

它仍然很快，但不像以前那么简洁。为了进行比较，这里是基于 Map- ping 的代码，这里只需要进行一些简单的修改：

Map[EuclideanDistance[#, refPoint] &, daList, {2}]

性能差异保持在相同的数量级，尽管矢量化解决方案由于需要进行非平凡的换位。