监控长时间运行的 PL/SQL 块

Question

我有一个相当耗时的 PL/SQL 块，它可以根据分子结构构建指纹。我想将输出打印到 SQL*Plus 控制台，以提供有关已处理的结构数量的反馈。我可以使用 dbms_output.put_line 来完成此操作，

但是每次调用都会写入新行。我想覆盖该行。

例如，目前我有以下内容。

Structure x of y processed
Structure x of y processed
Structure x of y processed
Structure x of y processed

最终，当我处理数千条结构记录时，我填满了缓冲区。

我可以使用一种方法来覆盖最后一个输出行吗？

Answer 1

使用 DBMS_OUTPUT 意味着 SQL*Plus 在整个 PL/SQL 块完成之前不会显示任何内容，然后显示缓冲区中当前的所有数据。因此，这不是提供持续状态的适当方式。

另一方面，Oracle 确实提供了一个专门为帮助您而设计的包 DBMS_APPLICATION_INFO监视您正在运行的代码。例如，您可以执行以下操作：

CREATE PROCEDURE process_structures
AS
  <<other variable declarations>>

  rindex    BINARY_INTEGER;
  slno      BINARY_INTEGER;
  totalwork NUMBER := y; -- Total number of structures
  worksofar NUMBER := 0; -- Number of structures processed
BEGIN
  rindex := dbms_application_info.set_session_longops_nohint;

  FOR i IN (<<select structures to process>>)
  LOOP
    worksofar := worksofar + 1;
    dbms_application_info.set_session_longops(
        rindex      => rindex, 
        slno        => slno,
        op_name     => 'Processing of Molecular Structures', 
        sofar       => worksofar , 
        totalwork   => totalwork, 
        target_desc => 'Some description',
        units       => 'structures');
    <<process your structure with your existing code>>
  END LOOP;
END;

从单独的 SQL*Plus 会话中，您可以通过查询 V$SESSION_LONGOPS 视图来监视进度

SELECT opname,
       target_desc,
       sofar,
       totalwork,
       units,
       elapsed_seconds,
       time_remaining
  FROM v$session_longops
 WHERE opname = 'Processing of Molecular Structures';

Answer 2

您还可以将消息发送到命名管道，并让另一个进程从管道中读取消息。

   procedure sendmessage(p_pipename varchar2
                        ,p_message  varchar2) is
      s number(15);
   begin
      begin
         sys.dbms_pipe.pack_message(p_message);
      exception
         when others then
            sys.dbms_pipe.reset_buffer;
      end;

      s := sys.dbms_pipe.send_message(p_pipename, 0);

      if s = 1
      then
         sys.dbms_pipe.purge(p_pipename);
      end if;
   end; 


   function receivemessage(p_pipename varchar2
                          ,p_timeout  integer) return varchar2 is
      n   number(15);
      chr varchar2(200);
   begin
      n := sys.dbms_pipe.receive_message(p_pipename, p_timeout);

      if n = 1
      then
         return null;
      end if;

      sys.dbms_pipe.unpack_message(chr);
      return(chr);
   end;

Answer 3

我认为你不能。据我了解 dbms_output 它只是不能那样工作。

我建议您使用 put 每隔 1000 个左右的条目回显一个点和一个换行符，以查看正在发生的情况，并将当前位置写入表中或对当前位置进行排序，以便您可以查看是否想知道。