perl：如何分割？

Question

我有一个字符串 aa:bb::cc:yy:zz ，需要以这样的方式进行拆分，以便我有一个包含 aa:bb::cc 的数组， yy，zz。即我想从最后创建两个子字符串，以 : 作为分隔符，并保留为数组的元素。实现这一目标的最佳方法是什么？

例如：

aa:bb::cc:yy:zz --> ['aa:bb::cc','yy','zz']

dd:ff:gg:dd:ee:ff:fg --> ['dd:ff:gg:dd:ee','ff','gg']

我将 IP 地址：端口：协议作为密钥存储在文件中，并用“：”拆分以获取 IP、端口、协议，当 IP 地址限制为 Ipv4 时，一切正常。现在我想将其移植到Ipv6，在这种情况下IP地址包含“：”，所以我无法通过用“：”分割来获得正确的IP地址。

Answer 1

怎么样：

#!/usr/local/bin/perl 
use Data::Dump qw(dump);
use strict;
use warnings;

my $x = 'dd:ff:gg:dd:ee:ff:fg';
my @l = $x =~ /^(.*?):([^:]+):([^:]+)$/g;
dump @l;

输出：

("dd:ff:gg:dd:ee", "ff", "fg")

Answer 2

当 $string 包含 2 个或更少对时，此代码将纠正处理情况：

my $string = 'aa:bb::cc:yy:zz';
my @data = split /:/, $string;
if (@data > 2) {
    unshift @data, join ':', splice @data, 0, -2;
}

# $string = 'aa:bb::cc:yy:zz';
# @data contains ('aa:bb::cc', 'yy', 'zz')

# $string = 'aa:bb';
# @data contains ('aa', 'bb')

Answer 3

我会做一个过于激进的 split 然后进行连接。我认为当您不使用复杂的正则表达式进行分割时，结果更具可读性。所以：

my $string = 'aa:bb::cc:yy:zz';
my @split_string = split(/:/, $string);
my @result = (join(':', @split_string[0..scalar(@split_string)-3]), $split_string[-2], $split_string[-1]);
print join(', ', @result), "\n";

给你：

aa:bb::cc, yy, zz

在开始像这样索引它之前，你必须对 @split_string 进行一些数组边界检查。

Answer 4

$ perl -wE '$_="aa:bb::cc:yy:zz"; say join "\n", split /:([^:]+):([^:]+)$/, $_;'
aa:bb::cc
yy
zz

更新：您没有提到这是为了解析 IP 地址。如果是，您最好尝试在 CPAN 上查找模块

Answer 5

$ perl -e'$_="aa:bb::cc:yy:zz"; @f=/(.*):([^:]+):(.+)/; print "$_\n" for @f'
aa:bb::cc
yy
zz

$ perl -e'$_="dd:ff:gg:dd:ee:ff:fg"; @f=/(.*):([^:]+):(.+)/; print "$_\n" for @f'
dd:ff:gg:dd:ee
ff
fg