“内存不足”使用 perl 解析大型 (100 Mb) XML 文件时

Question

我在解析大型 (100 Mb) XML 文件时出现错误“内存不足”，

use strict;
use warnings;
use XML::Twig;

my $twig=XML::Twig->new();
my $data = XML::Twig->new
             ->parsefile("divisionhouserooms-v3.xml")
               ->simplify( keyattr => []);

my @good_division_numbers = qw( 30 31 32 35 38 );

foreach my $property ( @{ $data->{DivisionHouseRoom}}) {

    my $house_code = $property->{HouseCode};
    print $house_code, "\n";

    my $amount_of_bedrooms = 0;

    foreach my $division ( @{ $property->{Divisions}->{Division} } ) {

        next unless grep { $_ eq $division->{DivisionNumber} } @good_division_numbers;
        $amount_of_bedrooms += $division->{DivisionQuantity};
    }

    open my $fh, ">>", "Result.csv" or die $!;
    print $fh join("\t", $house_code, $amount_of_bedrooms), "\n";
    close $fh;
}

我该如何解决此错误问题？

Answer 1

处理不适合内存的大型 XML 文件是 XML::Twig< /a> 广告：

XML::Twig 的优点之一是它可以让您处理文件
不适合内存（顺便说一句，将 XML 文档作为
树非常消耗内存，扩展因子通常是
大约10）。

为此，您可以定义处理程序，该处理程序将在
特定元素已完全解析。在这些处理程序中，您可以
访问元素并按照您认为合适的方式处理它 (...)

---

问题中发布的代码根本没有利用 XML::Twig 的优势（使用 simplify 方法并不比 XML::Simple）。

代码中缺少的是“twig_handlers”或“twig_roots”，它们本质上会导致解析器高效地关注 XML 文档的相关部分。

如果没有看到 XML，很难判断是否逐块处理文档或<一个href="http://search.cpan.org/~mirod/XML-Twig-3.38/Twig_pm.slow#Processing_just_parts_of_an_XML_document">仅选择部分是可行的方法，但任何一个都应该解决这个问题。

因此，代码应如下所示（逐块演示）：

use strict;
use warnings;
use XML::Twig;
use List::Util 'sum';   # To make life easier
use Data::Dump 'dump';  # To see what's going on

my %bedrooms;           # Data structure to store the wanted info

my $xml = XML::Twig->new (
                          twig_roots => {
                                          DivisionHouseRoom => \&count_bedrooms,
                                        }
                         );

$xml->parsefile( 'divisionhouserooms-v3.xml');

sub count_bedrooms {

    my ( $twig, $element ) = @_;

    my @divParents = $element->children( 'Divisions' );
    my $id = $element->first_child_text( 'HouseCode' );

    for my $divParent ( @divParents ) {
        my @divisions = $divParent->children( 'Division' );
        my $total = sum map { $_->text } @divisions;
        $bedrooms{$id} = $total;
    }

    $element->purge;   # Free up memory
}

dump \%bedrooms;

Answer 2

请参阅 逐块处理 XML 文档部分http://search.cpan.org/perldoc?XML%3a%3aTwig" rel="nofollow">XML::Twig 文档，它具体讨论了如何处理逐部分记录文档，允许处理大型 XML 文件。