属性的点字符串

Question

我有一个类似于这样的字符串哈希：

Map map = ['a.b.c': 'Hi']

...我需要在 gradle 中使用它来扩展这样的表达式：

This is a greeting: ${a.b.c}

如果我将 gradle 复制任务与 Expand 一起使用，我将收到一条错误消息“没有这样的属性：a '。

有什么方法可以让 gradle/groovy 将该映射转换为我需要解析的属性吗？

Answer 1

我找不到内置的答案，但它是一个完整的、独立的方法，可以用作 Map 上的元方法来执行您想要的操作：

Map map = ['a.b.c': 'Hi', 'a.b.d': 'Yo', 'f.g.h': 'Howdy']

Map.metaClass.expandKeys = { separator = '.' ->
    def mergeMaps = { a, b ->
        b.each{ k, v ->
            if(a[k] && (v instanceof Map)) {
                mergeMaps(a[k], v)
            } else {
                a[k] = v
            }
        }
        a
    }
    delegate.inject([:]){ result, k, v ->
        mergeMaps(result, k.tokenize(separator).reverse().inject(v){last, subkey -> [(subkey):last] })
    }
}

assert map.expandKeys() == [a:[b:[c:"Hi", d:"Yo"]], f:[g:[h:"Howdy"]]]

它还允许使用与 .< 不同的分隔符/code>，只需将分隔符传递到 expandKeys 方法中

如果您想像普通函数一样使用它，那么您可以这样做：

Map map = ['a.b.c': 'Hi', 'a.b.d': 'Yo', 'f.g.h': 'Howdy']

def expandKeys = { Map input, separator = '.' ->
    def mergeMaps = { a, b ->
        b.each{ k, v ->
            if(a[k] && (v instanceof Map)) {
                mergeMaps(a[k], v)
            } else {
                a[k] = v
            }
        }
        a
    }
    input.inject([:]){ result, k, v ->
        mergeMaps(result, k.tokenize(separator).reverse().inject(v){last, subkey -> [(subkey):last] })
    }
}

assert expandKeys(map) == [a:[b:[c:"Hi", d:"Yo"]], f:[g:[h:"Howdy"]]]

除了合并映射之外，主要技巧是拆分然后反转每个键。然后可以向后构建最终的层次结构。另外，可能有更好的方法来处理合并，因为我不喜欢末尾悬挂的 a 。

Answer 2

我对 Gradle 一无所知，但也许这会有所帮助......

如果你有一个 Map

Map map = ['a.b.c': 'Hi']

那么你无法使用 'Hi' 检索值

map.a.b.c

相反，你必须使用：

map.'a.b.c'

或

map['a.b.c']

Answer 3

我不太确定您的需求是什么，但如果您只需要替换类似属性的标记，而不需要 Groovy 模板的全部功能，则可以将 filter() 方法与 Ant 结合使用ReplaceTokens 类比 expand() 更安全（也更快）。请参阅 Gradle 用户指南中的过滤文件。