Applescript 获取文件的上次打开日期

Question

我可以使用
将 modDate 设置为字符串形式的文件修改日期以获取文件的最后修改日期，以及
将 modDate 设置为字符串形式的文件的创建日期以获取文件的创建日期。

是否有类似 last opening date 的内容来获取文件上次打开的日期？

Answer 1

是的。有一个名为 kMDItemLastUsedDate 的 UNIX 命令，它返回目标项目上次使用的日期。

set the Last_opened_date to (do shell script "mdls -name kMDItemLastUsedDate " & quoted form of the POSIX path of theFile)

但是，此命令不会返回文字日期对象。相反，它返回 ISO 8601:2004 格式 (YYYY-MM-DD HH:MM:SS) 的日期对象，如果您尝试在其前面放置 date ，您将收到语法错误。

这是修改后的脚本：

property months : {"January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December"}

set the Last_opened_date to date convert_date(do shell script "mdls -name kMDItemLastUsedDate " & quoted form of the POSIX path of theFile)

on convert_date(passed_data)
    set prevTIDs to AppleScript's text item delimiters
    set AppleScript's text item delimiters to space
    set the ISO_date to the first text item of (passed_data as string)
    set AppleScript's text item delimiters to "-"
    set the date_parts to every text item of the ISO_date
    set the_year to the first text item of the date_parts
    set the_month to the second text item of the date_parts
    set the_day to the third text item of the date_parts
    set AppleScript's text item delimiters to space
    set the time_string to the second text item of (passed_data as string)
    set AppleScript's text item delimiters to prevTIDs
    return item (the_month as integer) of months & the_day & ", " & the_year & space & the time_string
end convert_date

Answer 2

我遇到的问题是想要获取仅在聚光灯元数据中可用的日期（图像文件的内容创建日期“kMDItemContentCreationDate” - 我认为来自相机的原始日期）。所以我想出了这个；注意：为了我自己的清晰/强迫症，我使用了“复制”和“讲述”。 “do shell script”有一个“as date”强制，但它只是给了我不同的错误。还有更简单、更好的“awk”可以做更多/更好的事情，但“-name”只给出您要求的一个 mdls 值。

(* 获取“metaDate”的 mdls 值，即许多可用元数据日期之一
“qpImg”是某个文件的“posix路径的引用形式”
awk 将其剥离为实际的日期/时间字符串 *)

tell current application to copy (do shell script ("mdls " & " -name " & metaDate & " " & qpImg & " | awk -F ' ' '/Date/ {print $3,$4};'")) to targDate

(* 采用“2012-01-19 14:37:38 -500”形式的 mdls 信息日期并使其成为苹果脚本。
“inText”是一个 posix 路径，会动态转换为其“引用形式”。
“%x %r”是“标准数字”日期和 12 小时时间，可以通过“as date”强制 *)

tell current application to set formtdDate to do shell script "date -j -f '%Y-%m-%d %H:%M:%S' " & quoted form of inText & " +'%x %r'"

—— 可以使用 xargs 将两者组合起来

tell current application to copy (do shell script ("mdls -name " & metaDate & " " & qpImg & " | awk -F ' ' '{print $3,$4};' | xargs -0 -I indate date -j -f '%Y-%m-%d %H:%M:%S' indate +'%x %r'")) to targDate

Answer 3

没有纯粹的 AppleScript 解决方案来获取文件的上次访问日期。使用 shell 工具的组合 stat 和 date 您可以构建一个提供上次打开日期的 AppleScript 辅助函数：

on LastOpenedDate(theFile)
    set theStr to do shell script "date -r $(stat -f %a " & quoted form of (POSIX path of theFile) & ") +%Y-%m-%dT%H:%M:%S"
    ISODateStrToDate(theStr)
end LastOpenedDate

该函数使用以下辅助函数来转换上次打开的时间戳，该时间戳以 ISO 8601 格式的字符串转换为 AppleScript 日期：

on ISODateStrToDate(theStr)
    set dt to (current date)
    set savedDelimeters to AppleScript's text item delimiters
    set AppleScript's text item delimiters to {"-", "T", ":"}
    set {dt's year, dt's month, dt's day, dt's hours, dt's minutes, dt's seconds} to (every text item of theStr)
    set AppleScript's text item delimiters to savedDelimeters
    return dt
end ISODateStrToDate

可以使用以下命令调用函数 LastOpenedDate一个alias、file 或 POSIX file 作为参数，例如：

LastOpenedDate(POSIX file "/var/log/system.log")

返回。

date "Saturday, August 27, 2011 4:04:52 PM"

在我的机器上

Answer 4

上述解决方案在我的 Mac 上均无法正常工作。我决定找出答案——为什么？事实证明，mdls shell 命令读取结果时没有考虑正确的时区。或者，它需要一些额外的帮助才能做到这一点，我不知道。 （由于某种原因，不使用 mdls 的解决方案也无法正常工作）。

我必须找到一个 AsObjC 解决方案，它可以在任何时区和时间获取正确的上次打开日期（Finder 视图中的文件）。避免其他本地化或日期格式硬编码问题：

use AppleScript version "2.4" -- Yosemite (10.10) or later
use framework "Foundation"
use scripting additions

set posixPath to POSIX path of (choose file)

set theURL to (current application's |NSURL|)'s fileURLWithPath:posixPath
set mdItem to current application's NSMetadataItem's alloc()'s initWithURL:theURL
(mdItem's valueForAttribute:"kMDItemLastUsedDate") as date