将分隔符添加到串联列表

Question

我发现了这个自定义 Excel 函数：

Function Join(source As Range, Optional delimiter As String) As String
'
' Join Macro
' Joins (concatenates) the values from an arbitrary range of cells,
' with an optional delimiter.
'

'optimized for strings
'   check len is faster than checking for ""
'   string Mid$ is faster than variant Mid
'   nested ifs allows for short-circuit + is faster than &

    Dim sResult As String
    Dim oCell As Range

    For Each oCell In source.Cells
        If Len(oCell.Value) > 0 Then
            sResult = sResult + CStr(oCell.Value) + delimiter
        End If
     Next

    If Len(sResult) > 0 Then
        If Len(delimiter) > 0 Then
            sResult = Mid$(sResult, 1, Len(sResult) - Len(delimiter))
        End If
    End If

    Join = sResult
End Function

我想调整它以在它组合创建列表的每个单元格之间显示逗号。

Answer 1

您发现的 UDF 有几个问题：

• 应使用“&”进行串联。不是“+”。
• 使用范围内的单元格比使用变体数组并且纯粹在 VBA 内部工作要慢。每次对 Excel 的调用都会对性能产生微小的影响，而这种影响可能会累积起来。
• 如果连接正确完成，则无需转换为字符串。
• 应优化串联，以便首先连接较小的部分，然后将其添加到结果中，否则结果将被复制两次以执行每个串联。
• 名称不应该是 Join，因为 VBA 有一个具有该名称的函数。
• 不需要检查分隔符的 LEN，因为它是一个字符串。默认情况下，如果不存在，则为 LEN(0)，您可以从 len(result) 中减去 0，无需担心。
• 没什么大不了的，但检查不平等<>比 > 稍快。

这是我的版本。默认情况下，如果将第二个参数留空，它将用“,”分隔每个单元格（例如=ConcatenateRange(A1:A100)

Function ConcatenateRange(ByVal cell_range As range, _
                    Optional ByVal seperator As String = ", ") As String

Dim cell As range
Dim newString As String
Dim vArray As Variant
Dim i As Long, j As Long

vArray = cell_range.Value

For i = 1 To UBound(vArray, 1)
    For j = 1 To UBound(vArray, 2)
        If Len(vArray(i, j)) <> 0 Then
            newString = newString & (seperator & vArray(i, j))
        End If
    Next
Next

If Len(newString) <> 0 Then
    newString = Right$(newString, (Len(newString) - Len(seperator)))
End If

ConcatenateRange = newString

End Function

Answer 2

看起来它已经使用可选的 delimiter 参数执行此操作。

就像这样称呼它：

=JOIN(A1:A100,",")