Visual Basic 使用 ReadXml 设置用户代理

Question

我正在尝试使用 XmlRead 设置请求的用户代理。我用谷歌搜索了很多关于这个问题的信息，但找不到答案。这是我的代码块：

 Dim RssData As DataSet
        Dim Title As String
        Dim Url As String
        Dim Stream As String
        Dim buffer As Integer
        RssData = New DataSet()
        RssData.ReadXml("http://localhost/user_agent.php")
        buffer = 0
        For Each RssRow As DataRow In RssData.Tables("entry").Rows
            Title = Microsoft.VisualBasic.Left(RssRow.Item("title").ToString, 30)
            Stream += Title & vbCrLf

        Next
        LinkLabel3.Text = Stream

        For Each RssRow As DataRow In RssData.Tables("entry").Rows
            Title = Microsoft.VisualBasic.Left(RssRow.Item("title").ToString, 30)
            Url = RssRow.Item("url").ToString
            LinkLabel3.Links.Add(buffer, Title.Length, Url)
            buffer = buffer + Title.Length + 2
        Next

Answer 1

实际执行 Web 请求的代码部分埋藏得很深，因此您必须继承一堆代码才能执行您要求的操作。相反，我建议采用不同的路径，使用易于设置标头的代码自行下载 XML，然后将其加载到数据集中。 WebClient 类允许您设置任意标头，并具有简单的 DownloadString 方法。获得后，您可以将其包装在 MemoryStream 中，并将其传递给 ReadXml()。 （我找不到将 XML 作为字符串读取的方法，这就是我被迫将其作为 Stream 读取的原因。）

    ''//Will hold our downloaded XML
    Dim MyXml As String

    ''//Create a webclient to download our XML
    Using WC As New System.Net.WebClient()
        ''//Manually set the user agent header
        WC.Headers.Add("user-agent", "your user agent here")
        ''//Download the XML
        MyXml = WC.DownloadString("http://localhost/user_agent.php")
    End Using
    ''//Create our dataset object
    Dim RssData As New DataSet()
    ''//There is no direct method to load XML as a string (at least that I could find) so we will
    ''//    convert it to a byte array and load it into a memory stream
    Dim Bytes As Byte() = System.Text.Encoding.UTF8.GetBytes(MyXml)
    Using MS As New System.IO.MemoryStream(Bytes)
        ''//Load the stream into the reader
        RssData.ReadXml(MS)
    End Using

    ''//Your code continues normally here