如何在 Perl 中编写 *文件名* 包含 utf8 字符的文件？

Question

我正在努力创建一个包含非 ASCII 字符的文件。

如果使用 0 作为参数调用以下脚本，则它可以正常工作，但在使用 1 调用时会终止。

错误消息为open: Invalid argument at C:\temp\filename.pl line 15。

脚本在cmd.exe内启动。

我希望它写入一个名称为（取决于参数）äöü.txt 或 äöü☺.txt 的文件。但我无法创建包含笑脸的文件名。

use warnings;
use strict;

use Encode 'encode';

#   Text is stored in utf8 within *this* file.
use utf8;

my $with_smiley = $ARGV[0];

my $filename = 'äöü' . 
  ($with_smiley ? '☺' : '' ).
   '.txt';

open (my $fh, '>', encode('cp1252', $filename)) or die "open: $!";

print $fh "Filename: $filename\n";

close $fh;

我可能遗漏了一些对其他人来说显而易见的东西，但我找不到，所以我很感激任何解决这个问题的指示。

Answer 1

首先，说“UTF-8字符”很奇怪。 UTF-8可以对任何Unicode字符进行编码，因此UTF-8字符集就是Unicode字符集。这意味着您想要创建名称包含 Unicode 字符的文件，更具体地说，是 cp1252 中不包含的 Unicode 字符。

我过去在 PerlMonks 上回答过这个问题。答案复制如下。

---

Perl 将文件名视为不透明的字节字符串。这意味着文件名需要根据您的“区域设置”的编码（ANSI 代码页）进行编码。

在Windows中，通常使用代码页1252，因此编码通常为< code>cp1252。* 但是，cp1252 不支持泰米尔语和印地语字符[或“☺”]。

Windows 还提供了“Unicode”又名“Wide”接口，但 Perl 不提供使用内置函数**对其进行访问。您可以使用 Win32API::File 的 CreateFileW ， 尽管。 IIRC，您仍然需要自己对文件名进行编码。如果是这样，您可以使用 UTF-16le 作为编码。

前面提到的 Win32::Unicode 似乎可以处理使用 Win32API::File 为您服务。我也建议从那开始。

* — 代码页由 GetACP 系统调用返回（作为数字）。前面加上“cp”以获取编码。

** — Perl 对 Windows 的支持在某些方面很糟糕。

Answer 2

以下运行在 Windows 7 ActiveState Perl 上。它将“hello There”写入名称中包含希伯来语字符的文件中：

#-----------------------------------------------------------------------
# Unicode file names on Windows using Perl
# Philip R Brenan at gmail dot com, Appa Apps Ltd, 2013
#-----------------------------------------------------------------------

use feature ":5.16";
use Data::Dump qw(dump);
use Encode qw/encode decode/;
use Win32API::File qw(:ALL);

# Create a file with a unicode name

my $e  = "\x{05E7}\x{05EA}\x{05E7}\x{05D5}\x{05D5}\x{05D4}".
         "\x{002E}\x{0064}\x{0061}\x{0074}\x{0061}"; # File name in UTF-8
my $f  = encode("UTF-16LE", $e);  # Format supported by NTFS
my $g  = eval dump($f);           # Remove UTF ness
   $g .= chr(0).chr(0);           # 0 terminate string
my $F  = Win32API::File::CreateFileW
 ($g, GENERIC_WRITE, 0, [], OPEN_ALWAYS, 0, 0); #  Create file via Win32API
say $^E if $^E;                   # Write any error message

# Write to the file

OsFHandleOpen(FILE, $F, "w") or die "Cannot open file";
binmode FILE;                      
print FILE "hello there\n";      
close(FILE);

Answer 3

不需要对文件名进行编码（至少在 Linux 上不需要）。这段代码适用于我的 Linux 系统：

use warnings;
use strict;

#   Text is stored in utf8 within *this* file.
use utf8;

my $with_smiley = $ARGV[0] || 0;

my $filename = 'äöü' .
  ($with_smiley ? '?' : '' ).
     '.txt';

open my $fh, '>', $filename or die "open: $!";

binmode $fh, ':utf8';

print $fh "Filename: $filename\n";

close $fh;

HTH，Paul