F# 中通用测量单位结构的奇怪错误和其他奇怪行为

Question

我有这种类型：

type Vector3<[<Measure>]'u> =
    struct
        val x:float32<'u>
        val y:float32<'u>
        val z:float32<'u>
    end

    new(x, y, z) = { x = x; y = y; z = z }

当我尝试创建默认实例时，它给了我一个奇怪的错误，我在 Google 上找不到任何相关信息：

错误 5 仅当结构类型的所有字段都接受默认初始化时，才可以使用结构类型的默认零初始化构造函数

所以好吧，我可以使用默认构造函数将所有内容设置为 0和。或不。

let f = Vector3(0.f<N>, 0.f<N>, 0.f<N>)

给我一个错误：

错误 1 ​​该表达式的类型应为 float32，但此处的类型为 float32

这似乎仅在我在后续计算中使用此实例时才会发生；否则，它会正确地将 f 的类型解析为 Vector3。为构造函数提供类型，如 Vector3(...) 似乎也解决了问题，这确实很奇怪。

我做错了什么吗？

Answer 1

您的代码中的其他地方一定有问题。如果您重置 F# Interactive，打开一个新的空 F# 脚本文件并粘贴以下代码（然后在 FSI 中运行它），那么一切对我来说都很好：

type Vector3<[<Measure>]'u> =
    struct
        val x:float32<'u>
        val y:float32<'u>
        val z:float32<'u>
    end
    new(x, y, z) = { x = x; y = y; z = z }

[<Measure>] type N    
let f = Vector3(0.f<N>, 0.f<N>, 0.f<N>) 

我建议使用更简洁的隐式构造函数语法编写代码更惯用的 F#（仍然允许使用 struct .. end 声明，但它主要在旧版本的 F# 中使用）。默认构造函数似乎在这种情况下不起作用，但您可以使用静态成员：

[<Struct>]
type Vector3<[<Measure>]'u>(x:float32<'u>, y:float32<'u>, z:float32<'u>) =
    member this.X = x    
    member this.Y = y
    member this.Z = z
    static member Empty : Vector3<'u> = Vector3(0.f<_>, 0.f<_>, 0.f<_>)

[<Measure>] type N

let f1 = Vector3<N>.Empty
let f2 = Vector3(0.f<N>, 0.f<N>, 0.f<N>) 
f1.X + f2.X

Answer 2

您需要为 val 字段指定默认值属性：

type Vector3<[<Measure>]'u> =
    struct
        [<DefaultValue(false)>] val mutable x:float32<'u>
        [<DefaultValue(false)>] val mutable y:float32<'u>
        [<DefaultValue(false)>] val mutable z:float32<'u>
    end
    member X.Init(x,y,z) = 
        X.x <- x
        X.y <- y
        X.z <- z

或使用记录类型：

type Vector3<[<Measure>]'u> = { x : float32<'u>; y : float32<'u> ; z : float32<'u> }
[<Measure>] type N
let v = { x = 10.0F<N>; y = 10.0F<N>; z = 10.0F<N> }

更新：

type Vector3<[<Measure>]'u> =
    struct
        val x:float32<'u>
        val y:float32<'u>
        val z:float32<'u>
        new(X, Y, Z) = { x = X; y = Y; z = Z }
    end