真正删除 XMLParser Object Groovy 中的节点

Question

如何通过 XMLParser 真正删除节点：

 x='''<X>
<A>
 <B c3='1'>
   <C1>a</C1>
   <C2>b</C2>
 </B>
 <B c3='2'>
   <C1>e</C1>
   <C2>e</C2>
 </B>
 <B c3='3'>
   <C1>f</C1>
   <C2>f</C2>
 </B>
</A>
</X>
'''

xml=new XmlParser().parseText(x)
def nodeToDel=xml.A.B.find{it.@C1='a'}
xml.remove(nodeToDel)
println xml
new XmlNodePrinter(new PrintWriter(new FileWriter(new File('c:/temp/a.xml')))).print(xml)

似乎可行，但是！！！！ 当我将其翻译为我的问题时，它仍然保存原始的 xml，尽管在运行删除方法后返回 true。

我用谷歌搜索了一下，发现了这个BUG。看来我现在受到了影响。我该如何解决它？有没有解决方法，或者我必须回到根源并开始按行复制它......？ groovy 在这里真的很不好吗 :-/

编辑：正如下面所写的，并从中获得了经验，不可能以这种方式删除等于“e”的标签。仅第一条记录将被删除。我认为xml格式有问题。没有所需的格式：

并采用

格式12

有人能够重现这个错误吗？

edit2：我使用的是 GroovyConsole 1.8.0。将 c3 属性添加到示例中。尝试用相同的方法删除它，同样的错误：第一个 B 部分被删除...... 现在最令人印象深刻的错误：用其他代码尝试：

def xml=new XmlParser().parseText(x)
xml.A.remove(xml.A.B.find{it.@'c3'= '3'}) //want to remove third section
new XmlNodePrinter(new PrintWriter(new FileWriter(new File('c:/temp/a.xml')))).print(xml)

结果第一部分的属性 c3 更改为 3 ?!?!?!?!? wtf...

我现在正在尝试寻找解决方案一个星期，这真是太累了...

有人有想法吗？

Answer 1

删除节点的工作方式与其他 DOM API 非常相似。您必须将要删除的节点传递给其父节点的删除方法。

另外，= 运算符是 Groovy 中的赋值运算符。 it.@C1 = 'a' 会将 'a' 分配给每个 B 节点的 C1 属性该文件。由于该赋值的结果是 'a'，它被 Groovy 强制为 true，因此 find 将始终返回它遇到的第一个节点。

xml=new XmlParser().parseText(x)
def nodeToDel=xml.A.B.C1.find { it.text() == 'a' }
def parent = nodeToDel.parent()
parent.remove(nodeToDel)

Answer 2

改进Justin Piper的解决方案，并提供一个完整的工作示例：

def xml = new XmlParser().parseText('''
    <root>
        <element id="10" />
        <element id="20" />
    </root>
''')
def nodeToDel = xml.find { it["@id"] == '20' }

if (nodeToDel) {
    nodeToDel.parent().remove(nodeToDel)
}

println xml