Delphi 中的 AccessViolationException - 不可能（检查一下，难以置信......）

Question

德尔福XE。 Windows 7。

有一个函数（请参阅下面的代码）或 I:=0 会在大型项目中导致 AV 错误。在新项目中同样的功能没有报错！！！我删除了大项目中的所有内容，只留下了一个按钮和该功能。它仍然会导致错误...

一行错误：

if ISAeroEnabled then // this line is a cause
       i:=0;         // or this line

我在各处设置了断点（我检查了整个函数，我在每行上设置了断点 -> 函数中没有错误），调试器显示错误位于 i:=0;

如果要删除函数（并保留 i:=0;） -> 一切正常！

错误消息：首次机会异常，价格为 747FB727。异常类 EAccessViolation，带有消息“模块‘MngProject.exe’中地址 004AE5AF 处的访问冲突”。写入地址0017FFF8'。 Process MngProject.exe (4980)

为什么它在新项目中有效，但在我的项目中无效？

这是整个项目：http://www.2shared.com/file/UP22Om4j/Bug。 html

代码：

unit MainFormModule;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  StdCtrls;
type
  TMainForm = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public

    { Public declarations }
  end;

var
     mainform:tmainform;
implementation
{$R *.dfm}

function  ISAeroEnabled: Boolean;
type
  _DwmIsCompositionEnabledFunc = function(IsEnabled: PBoolean): HRESULT; stdcall;
var
  Flag                       : Boolean;
  DllHandle                  : THandle;
  OsVersion                  : TOSVersionInfo;
  DwmIsCompositionEnabledFunc: _DwmIsCompositionEnabledFunc;
begin
  Result:=False;
  ZeroMemory(@OsVersion, SizeOf(OsVersion));
  OsVersion.dwOSVersionInfoSize := SizeOf(TOSVERSIONINFO);

  if ((GetVersionEx(OsVersion)) and (OsVersion.dwPlatformId = VER_PLATFORM_WIN32_NT) and (OsVersion.dwMajorVersion >= 6)) then //is Vista or Win7?
  begin
    DllHandle := LoadLibrary('dwmapi.dll');
    if DllHandle <> 0 then
    begin
      @DwmIsCompositionEnabledFunc := GetProcAddress(DllHandle, 'DwmIsCompositionEnabled');
      if (@DwmIsCompositionEnabledFunc <> nil) then
      begin
        DwmIsCompositionEnabledFunc(@Flag);
        Result:=Flag;
      end;
    end;
      FreeLibrary(DllHandle);
  end;
end;

procedure Tmainform.Button1Click(Sender: TObject);
var i:integer;
begin
    if ISAeroEnabled then // AV is here
       i:=0;              // Or here
end;
end.

Answer 1

尝试将 PBoolean 更改为 PBOOL

function(IsEnabled: PBOOL): HRESULT; stdcall;

var
  Flag: BOOL;

PBoolean 是一个指向 Pascal Boolean 的指针，大小为 1 个字节。 PBOOL 是一个指向 Windows（基于 C）BOOL 的指针，大小为 4 个字节。您需要匹配 Windows 期望的大小。

通常，将 Windows API 调用转换为 Delphi 时，请使用与 API 相同的命名数据类型。 Windows.pas 具有将这些映射到 Delphi 类型的类型定义，例如 type BOOL = LongBool;

另外，在 Delphi 中通常（但不是必需）将指针参数更改为 var。 var 参数是用于传递引用的 Pascal 语法糖，在 C 中不可用。

function(var IsEnabled: BOOL): HRESULT; stdcall;
....
    DwmIsCompositionEnabledFunc(Flag); // no @ operator

注意： 我无法测试这一点，因为我只有 XP 可用。