如何使用 xsl 连接具有两个不同分隔符的字符串

Question

我有一个 XML

<main>
  <DATA_RECORD>
    <COMPONENT_SID>100</COMPONENT_SID>
    <GROUP_ID>1</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>200</COMPONENT_SID>
    <GROUP_ID>1</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>400</COMPONENT_SID>
    <GROUP_ID>1</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>10</COMPONENT_SID>
    <GROUP_ID>2</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>20</COMPONENT_SID>
    <GROUP_ID>2</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>2</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>4</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>8</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  <DATA_RECORD>
    <COMPONENT_SID>16</COMPONENT_SID>
    <GROUP_ID>3</GROUP_ID>
  </DATA_RECORD>
  </main>

，我想使用 xsl 解析为另一个 XML。输出将是

<comp value="100,200,400|10,20|2,4,8,16"/> 

属于不同 group_id 的 component_sids 用“|”分隔。属于同一组id的component_sids应该用“,”连接。我使用了以下xsl，

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:template match="/">
          <xsl:element name="comp">
             <xsl:attribute name="value">
                 <xsl:call-template name="join"> 
                        <xsl:with-param name="list" select="//DATA_RECORD[GROUP_ID=1]/COMPONENT_SID" /> 
                        <xsl:with-param name="separator" select="','" />                                             
                  </xsl:call-template> 
              </xsl:attribute>
        </xsl:element>
  </xsl:template>

   <xsl:template name="join"> 
    <xsl:param name="list" /> 
    <xsl:param name="separator"/>     
    <xsl:for-each select="$list"> 
      <xsl:value-of select="." /> 
      <xsl:if test="position() != last()"> 
        <xsl:value-of select="$separator" />         
      </xsl:if> 
    </xsl:for-each> 
  </xsl:template> 
</xsl:stylesheet>

结果是

<comp value="100,200,400"/>

但我无法弄清楚如何用“|”分隔其他组的component_sid。有人可以帮助我吗？

提前致谢

Answer 1

XSLT 2.0 解决方案可以进一步缩短为：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>

<xsl:template match="/">
  <xsl:variable name="vResult">
   <xsl:for-each-group select="*/*" group-by="GROUP_ID">
    <xsl:if test="not(position()=1)">|</xsl:if>
    <xsl:value-of select="current-group()/COMPONENT_SID" separator=","/>
   </xsl:for-each-group>
  </xsl:variable>

  <comp value="{$vResult}"/>
 </xsl:template>
</xsl:stylesheet>

Answer 2

我。 XSLT 1.0 解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kRecByGrId" match="DATA_RECORD"
                            use="GROUP_ID"/>

 <xsl:variable name="vGrIds" select=
 "/*/DATA_RECORD
      [generate-id()
      =
       generate-id(key('kRecByGrId', GROUP_ID)[1])
       ]
        /GROUP_ID
 "/>

 <xsl:template match="/">
   <xsl:variable name="vResult">
       <xsl:for-each select="$vGrIds">
        <xsl:if test="not(position()=1)">|</xsl:if>
        <xsl:apply-templates select=
          "key('kRecByGrId', .)/COMPONENT_SID"/>
       </xsl:for-each>
     </xsl:variable>

     <comp value="{$vResult}"/>
 </xsl:template>

 <xsl:template match="COMPONENT_SID">
      <xsl:if test="not(position()=1)">,</xsl:if>
      <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<main>
    <DATA_RECORD>
        <COMPONENT_SID>100</COMPONENT_SID>
        <GROUP_ID>1</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>200</COMPONENT_SID>
        <GROUP_ID>1</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>400</COMPONENT_SID>
        <GROUP_ID>1</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>10</COMPONENT_SID>
        <GROUP_ID>2</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>20</COMPONENT_SID>
        <GROUP_ID>2</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>2</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>4</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>8</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
    <DATA_RECORD>
        <COMPONENT_SID>16</COMPONENT_SID>
        <GROUP_ID>3</GROUP_ID>
    </DATA_RECORD>
</main>

产生所需的正确结果：

<comp value="100,200,400|10,20|2,4,8,16"/>

说明：

1. < strong>Muenchian 分组方法 -- 查找 GROUP_ID 的所有不同值。

2. 只要该项目（或组）不是第一个，就在项目（或组）之前添加分隔符的简单逻辑。

二. XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:variable name="vResult">
   <xsl:for-each-group select="*/*" group-by="GROUP_ID">
    <xsl:if test="not(position()=1)">|</xsl:if>
    <xsl:for-each select="current-group()/COMPONENT_SID">
      <xsl:if test="not(position()=1)">,</xsl:if>
      <xsl:value-of select="."/>
    </xsl:for-each>
   </xsl:for-each-group>
  </xsl:variable>

     <comp value="{$vResult}"/>
 </xsl:template>
</xsl:stylesheet>

当应用于同一个 XML 文档（上面）时，再次生成所需的正确结果：

<comp value="100,200,400|10,20|2,4,8,16"/>

说明：

1. 使用 < code>

2. 使用current-group()

3. 在每个项目（或组）之前使用相同的简单逻辑，但不是第一个，带有相应的分隔符。