当结果可能为空时，如何选择 PL/SQL 中的变量？

Question

有没有办法只运行一次查询来选择变量，考虑到查询可能不返回任何内容，那么在这种情况下变量应该为空。

目前，我无法直接select into 变量，因为如果查询不返回任何内容，PL/SQL 会抱怨变量未设置。我只能运行查询两次，第一次执行计数，如果计数为零，则将变量设置为 null，如果计数为 1，则选择变量。

所以代码应该是这样的：

v_column my_table.column%TYPE;
v_counter number;
select count(column) into v_counter from my_table where ...;
if (v_counter = 0) then
    v_column := null;
elsif (v_counter = 1) then
    select column into v_column from my_table where ...;
end if;

谢谢。

更新： 我没有使用异常的原因是在分配v_column之后我仍然有一些以下逻辑，并且我必须在异常部分使用goto跳回以下内容代码。我对goto行有点犹豫。

Answer 1

您只需将变量设置为 NULL 即可处理 NO_DATA_FOUND 异常。这样，只需要一次查询。

    v_column my_table.column%TYPE;

BEGIN

    BEGIN
      select column into v_column from my_table where ...;
    EXCEPTION
      WHEN NO_DATA_FOUND THEN
        v_column := NULL;
    END;

    ... use v_column here
END;

Answer 2

我知道这是一个旧线程，但我仍然认为值得回答它。

select (
        SELECT COLUMN FROM MY_TABLE WHERE ....
        ) into v_column
from dual;

使用示例：

declare v_column VARCHAR2(100);
begin
  select (SELECT TABLE_NAME FROM ALL_TABLES WHERE TABLE_NAME = 'DOES NOT EXIST')
  into v_column 
  from dual;
  DBMS_OUTPUT.PUT_LINE('v_column=' || v_column);
end;

Answer 3

使用 MAX 怎么样？
这样，如果没有找到数据，则变量设置为 NULL，否则设置为最大值。
由于您期望 0 或 1 值，因此 MAX 应该可以使用。

v_column my_table.column%TYPE;
select MAX(column) into v_column from my_table where ...;

Answer 4

我最喜欢使用 游标 FOR LOOP 语句方法来做到这一点。

它比使用显式游标更安全，因为您不需要记住关闭它，因此您不能“泄漏”游标。

您不需要“进入”变量，不需要“FETCH”，不需要捕获和处理“NO DATA FOUND”异常。

尝试一下，你永远不会回去。

v_column my_table.column%TYPE;

v_column := null;

FOR rMyTable IN (SELECT COLUMN FROM MY_TABLE WHERE ....) LOOP
  v_column := rMyTable.COLUMN;
  EXIT;  -- Exit the loop if you only want the first result.
END LOOP;

Answer 5

从上面的所有答案来看，Björn 的答案似乎是最优雅和简短的。我个人多次使用过这种方法。 MAX 或 MIN 函数同样可以很好地完成这项工作。完整的 PL/SQL 如下，只需指定 where 子句。

declare v_column my_table.column%TYPE;
begin
    select MIN(column) into v_column from my_table where ...;
    DBMS_OUTPUT.PUT_LINE('v_column=' || v_column);
end;

Answer 6

我建议使用光标。游标获取始终是单行（除非您使用批量集合），并且游标不会自动抛出 no_data_found 或 Too_many_rows 异常；尽管您可以在打开后检查游标属性以确定是否有一行以及有多少行。

declare
v_column my_table.column%type;
l_count pls_integer;
cursor my_cursor is
  select count(*) from my_table where ...;

begin
  open my_cursor;
    fetch my_cursor into l_count;
  close my_cursor;

  if l_count = 1 then
    select whse_code into v_column from my_table where ...;
  else
    v_column := null;
  end if;
end;

或者，更简单：

    declare
    v_column my_table.column%type;
    cursor my_cursor is
      select column from my_table where ...;

    begin
      open my_cursor;
        fetch my_cursor into v_column;
        -- Optional IF .. THEN based on FOUND or NOTFOUND
        -- Not really needed if v_column is not set
        if my_cursor%notfound then
          v_column := null;
        end if;
      close my_cursor;
    end;

Answer 7

我使用这种语法是为了灵活性和速度 -

    begin
    --
    with KLUJ as
    ( select 0 ROES from dual
       union 
      select count(*) from MY_TABLE where rownum = 1
    ) select max(ROES) into has_rows from KLUJ;
    --
    end;

Dual 返回 1 行，rownum 添加 0 或 1 行，max() 组恰好为 1。这对于表中没有行给出 0，对于任何其他行数给出 1。

我扩展了 where 子句以按条件对行进行计数，删除 rownum 以对满足条件的行进行计数，并增加 rownum 以对满足条件的行进行计数直至达到限制。

Answer 8

COALESCE 将始终返回第一个非空结果。通过这样做，你将得到你想要的计数或 0：

select coalesce(count(column) ,0) into v_counter from my_table where ...;