如何全局关闭隐藏消息（符号::shdw）？或任何其他“良好实践”；建议？

Question

我有以下情况：

On[t::shdw]

Message[t::shdw,"t","Foobar","Dork"]
-> t::shdw: Symbol t appears in multiple contexts Foobar; definitions in context Dork may shadow or be shadowed by other definitions. >>

Off[t::shdw]
Message[t::shdw,"t","Foobar","Dork"]
-> **No Warning**

<<MASStoolbox`
-> t::shdw: Symbol t appears in multiple contexts {MASStoolbox`MASS`,Global`}; definitions in context MASStoolbox`MASS` may shadow or be shadowed by other definitions. >>

怎么可能？ On和Off是否只影响当前Notebook，加载包时没有任何效果？如果是这样，如何摆脱这样的消息呢？应该如何处理阴影错误？

Answer 1

您观察到的原因是语句 Off[t::shdw] 禁用了当前位于 $ContextPath< 上的符号 t 的隐藏消息/code>，但不适用于在加载另一个包期间创建的另一个 t。如果您不想看到第二个 t，您应该禁用它。这是一个示例：

In[1]:= Off[Test1`a::shdw]
In[2]:= 
BeginPackage["Test`"]
a
EndPackage[]

Out[2]= Test`
Out[3]= a

In[5]:= BeginPackage["Test1`"]
a
EndPackage[]

Out[5]= Test1`
Out[6]= a

这里没有生成任何消息。

不过，一般来说，我不想禁用隐藏消息，因为隐藏是一个严重的问题。隐藏只是意味着符号搜索路径 ($ContextPath) 上当前存在多个上下文，其中包含具有相同（短）名称的符号。基本上，如果符号被隐藏，并且您通过其短名称引用它（即，不包含其包含包的符号），您无法保证具有相同短名称的几个符号中的哪一个实际上将被使用。因此，处理这个问题的正确方法是完全避免阴影，这总是可能的，尽管并不总是方便。

避免阴影的最简单方法是将所需的包加载到包的私有部分，该部分在 Begin["`Private`"] 行之后开始。与往常一样，您可以通过调用 Needs[your-package] 来完成此操作。这样，加载的包的上下文不会与包的上下文一起保留在 $ContextPath 上。最糟糕的情况是当您需要加载两个具有冲突符号的包时。一种解决方法是为其中之一构建一个包装程序包，该包装程序包将私下加载该程序包并重命名冲突的符号。但这可能很不方便，因为您必须重命名包中的所有函数，即使是那些不冲突的函数。下面是一个更灵活变体的示例：

第一个包：

BeginPackage["Test`"];
g[x_?NumericQ] := x^2;
EndPackage[];

第二个包：

BeginPackage["Test1`"];
g[x_?NumericQ] := x^3;
EndPackage[]

主包：

BeginPackage["Main`"];
f::usage = "A test function of a single  argument";
Begin["`Private`"];

Block[{$ContextPath = $ContextPath},
  Needs["Test`"];
  (* Define first delegate private function *)
  g1 = Symbol["g"]];


Block[{$ContextPath = $ContextPath},
  Needs["Test1`"];
  (* Define second delegate private function *)
  g2 = Symbol["g"];
];

f[x_] := g1[x]*g2[x]
End[]
EndPackage[]

现在，假设系统知道在哪里可以找到您的包：

In[2]:= Needs["Main`"]

In[3]:= f[x]
Out[3]= Test`g[x] Test1`g[x]

In[4]:= f[2]
Out[4]= 32

我们对同一个公共函数使用了两个冲突的符号。使用上面的 Block 可以本地化使用 g 第一个或第二个定义的代码。请注意，此方法有一些不便，因为我们需要使用 Symbol["your-symbol-name"] 将解析延迟到运行时。

一个非常简单的方法是仅通过符号的长名称来引用它们。在上面，我们可以只使用 Test`g 和 Test1`g ，然后就不需要重型机械了。然而，这有点不太灵活，因为您必须将符号的上下文“硬编码”到代码中。

Answer 2

您可以重载 Message 将其关闭：

Unprotect@Message;
Message[MessageName[s_, "shdw"],___] := Null;
Protect@Message;

此代码还会发出更有用且更正确的消息，并使用 Assert:

Unprotect@Message;
Message[MessageName[s_, "shdw"], 
   rest : PatternSequence[snHeld_, pathsHeld_, newpath_]] := 
  With[{paths = ReleaseHold@pathsHeld},
   {memberpaths = Select[$ContextPath, MemberQ[paths, #] &], 
    sn = ReleaseHold@snHeld},
   Print@StringTemplate[
      "Note: Symbol `` added in context ``, so that it now appears in \
multiple contexts: ``. On the context path, it is currently found in: \
``. Definitions in the first context of the context path, ``, will \
shadow any other definitions."][sn, newpath, paths, memberpaths, 
     First@memberpaths];
   (*symbol name*)
   Assert[SymbolName@s === sn];

   (*demonstrate that First@
   memberpaths is the context used for short names*)
   Assert[ToExpression@StringTemplate[
       "Unevaluated@`` === Unevaluated@````"
       ][sn, First@memberpaths, sn
      ]
    ];

   (*and not any other context*)
   Assert@AllTrue[TrueQ][ToExpression@StringTemplate[
          "Unevaluated@`` =!= Unevaluated@````"
          ][sn, #, sn
         ] & /@ DeleteCases[paths, First@memberpaths]
     ];
   ];
Protect@Message;

Try 验证其断言：

Global`Image 

注意：符号图像添加到上下文 Global` 中，以便它现在出现在多个上下文中：{Global`、System`}。在上下文路径上，当前可以在：{System`, Global`} 中找到它。上下文路径的第一个上下文 System` 中的定义将隐藏任何其他定义。

cf https://mathematica.stackexchange.com/questions/43381/result-about-context-is-inconcient-with-the-description-of-power-programming/119887#119887