减少 happstack 教程代码中的冗余

Question

happstack 教程提供了以下示例：

main :: IO ()
main = simpleHTTP nullConf $ msum 
       [ do methodM GET
            ok $ "You did a GET request.\n"
       , do methodM POST
            ok $ "You did a POST request.\n"
       , dir "foo" $ do methodM GET
                        ok $ "You did a GET request on /foo.\n"
       ]

看来 ok $ 在这里是多余的 - 有没有什么方法可以将其从 msum 中提取出来，这样您就不必写三遍ok $？我尝试了以下操作，但它甚至无法编译：

main :: IO ()
main = simpleHTTP nullConf $ ok $ msum 
       [ do methodM GET
            "You did a GET request.\n"
       , do methodM POST
            "You did a POST request.\n"
       , dir "foo" $ do methodM GET
                        "You did a GET request on /foo.\n"
       ]

是否有正确的方法来执行此操作（或者更好的是，拉出整个 ok $ "You did a " and " .\n")，还是根本不可能？

我仍在了解 monad 在 Haskell 中的工作原理，但如果上述情况不可能，那么您能否从高层次上解释一下为什么没有合理的方法来使其工作，或者需要更改哪些内容才能正常工作让它成为可能？我只是想弄清楚这里可以做什么和不能做什么。

Answer 1

ok 并不是真正多余。

让我们仔细看看其中一个 do 块。我们将第一个 do 块拆分为一个名为 getPart 的单独函数。

getPart :: ServerPart String
getPart = do methodM GET
             ok $ "You did a GET request.\n"

因此，我们清楚地看到我们正在使用 ServerPart monad。因此，do 块中的每一行都必须具有类似 ServerPart a 的类型。

编写这样的代码不会工作：

getPart :: ServerPart String
getPart = do methodM GET
             "You did a GET request.\n"

因为 do 块中的最后一行的类型为 String 而不是 require ServerPart String。将 String 转换为 ServerPart String 的典型方法是使用 return：

getPart :: ServerPart String
getPart = do methodM GET
             return "You did a GET request.\n"

请记住 return 的类型为：

return :: (Monad m) => a -> m a

但是，当然，这并不比我们以前的情况好多少。我们没有 ok，而是 return。确实没有办法避免这种“样板”。您需要一个 ServerPart String 而不是 String，这意味着应用诸如 return 或 ok 之类的函数来完成提升。

正如您所注意到的，消息的“You did a”部分是多余的。我们可以通过多种方式来解决这个问题。我们可以让处理程序只返回消息中不同的部分，如下所示：

handlers :: ServerPart String
handlers = 
       [ do methodM GET
            ok $ "GET request"
       , do methodM POST
            ok $ "POST request"
       , dir "foo" $ do methodM GET
                        ok $ "GET request on /foo"
       ]

然后我们可以获得 String 并添加消息的其余部分：（

main :: IO ()
main = simpleHTTP nullConf $ do msg <- handlers
                                return ("You did a " ++ msg ++ ".\n")

这可以更紧凑地表达，但我我的目标是提高可读性）。

该解决方案的一个问题是它迫使所有这些处理程序都符合完全相同的模具。如果我们想添加一个返回不符合该模式的消息的处理程序，我们就会遇到麻烦。另一种选择是创建一个简单的辅助函数来封装该模式：

methodMsg :: Method -> String -> ServerPart String
methodMsg mthd msg = do methodM mthd
                        ok $ "You did a " ++ msg ++ ".\n"

main :: IO ()
main = simpleHTTP nullConf $ msum 
       [ methodMsg GET  "GET request"
       , methodMsg POST "POST request"
       , dir "foo" $ methodMsg GET "GET request on /foo"
       -- the bar handler does not follow the pattern
       , dir "bar" $ ok $ "let's go to the bar!"
       ]

希望这有帮助！

Answer 2

不确定 dir 的类型，但类似这样的东西应该可以工作：

main :: IO ()
main = simpleHTTP nullConf $ msum 
       [ do methodM GET
            return "GET request"
       , do methodM POST
            return "POST request"
       , dir "foo" $ do methodM GET
                        return "GET request on /foo"
       ] >>= ok . (\s -> "You did a " ++ s ++ ".\n")

对于如此短的块，我很想撤消它们：

main :: IO ()
main = simpleHTTP nullConf $ msum 
       [ methodM GET  >> return "GET request"
       , methodM POST >> return "POST request"
       , dir "foo" $ methodM GET >> return "GET request on /foo"
       ] >>= ok . (\s -> "You did a " ++ s ++ ".\n")