重构 F# 小函数

Question

我创建了以下 F# 函数，它将从网页的 html 内容中获取 url：

let getPicUrl (urlContents : string) =
  let START_TOKEN = "jpg_url="
  let startIndex = urlContents.IndexOf(START_TOKEN)
  let endIndex = urlContents.IndexOf("&amp", startIndex)
  let s = startIndex + START_TOKEN.Length
  let l = endIndex-startIndex-START_TOKEN.Length

  urlContents.Substring(s, l)

最​​后一行 urlContents.Substring(s, l) 实际需要的只是 s 和 l，所以我想知道是否可以将此函数的部分内容重构为一些内部函数，以便我的意图更加清晰。理想情况下，getPicUrl 只会有 2 个 let 指令，s 和 l，所有其他指令都是内部定义这些 let 指令。如果这能以任何方式实现，那就是另一个故事了。

目前我能想到的改进上述代码的唯一明显的方法是切换位置的 endIndex ，这样我们就可以了，

let getPicUrl (urlContents : string) =
  let START_TOKEN = "jpg_url="
  let startIndex = urlContents.IndexOf(START_TOKEN)
  let s = startIndex + START_TOKEN.Length
  let l =
    let endIndex = urlContents.IndexOf("&amp", startIndex)
    endIndex-startIndex-START_TOKEN.Length

  urlContents.Substring(s, l)

但是我一直想知道是否有一种更清晰的方法来组织这个函数的 let 定义。

Answer 1

首先，你的功能有问题。不匹配的字符串会让它变得脾气暴躁。

我喜欢用正则表达式来处理这类事情。使用此活动模式：

open System.Text.RegularExpressions

let (|Regex|_|) pattern input =
  let m = Regex.Match(input, pattern)
  if m.Success then Some(List.tail [for g in m.Groups -> g.Value])
  else None

您可以执行以下操作：

let tryGetPicUrl = function
  | Regex @"jpg_url=([^&]+)&" [url] -> Some url
  | _ -> None

您还可以将原始方法转变为活动模式：

let (|Between|_|) (prefix:string) (suffix:string) (value:string) =
  match value.IndexOf(prefix) with
  | -1 -> None
  | s ->
    let n = s + prefix.Length + 1
    match value.IndexOf(suffix, n) with
    | -1 -> None
    | e -> Some (value.Substring(n, e - n))

并执行以下操作：

let tryGetPicUrl = function
  | Between "jpg_url" "&" url -> Some url
  | _ -> None

Answer 2

你可以这样写：

let getPicUrl (urlContents : string) =
  let s =
    let START_TOKEN = "jpg_url="
    let startIndex = urlContents.IndexOf(START_TOKEN)
    startIndex + START_TOKEN.Length
  let l =
    let endIndex = urlContents.IndexOf("&", s)
    endIndex-s

  urlContents.Substring(s, l)

Answer 3

另一种选择是使用字符串的 split 方法（我希望字符串不要太长，否则会影响性能）并使用选项类型来指示是否找到 URL。

let getPicUrl (urlContents : string) =
    let splitAndGet n (sep:string) (str:string) = 
        let spl = str.Split([|sep|],StringSplitOptions.None)
        match spl.Length with
        | x when x > n -> Some (spl.[n])
        | _ -> None 
    match urlContents |> splitAndGet 1 "jpg_url=" with
    | Some str -> str |> splitAndGet 0 "&"
    | _ -> None