Linux 汇编；参数列表失控

Question

我对任何类型的汇编编程都很陌生，而且因为我听说 Linux 的 NASM 类型汇编比基于 DOS 的汇编相对简单，所以我决定尝试一下。

到目前为止，这是我的程序：

section .data
    opening:    db  'Opening file...',10
    openingLen: equ $-opening
    opened:     db  'File opened.',10
    openedLen:  equ $-opened
    bad_params: db  'Usage: writeFile filename.ext',10
    bad_paramsLen:  equ $-bad_params
    not_opened: db  'Unable to open file.  Halted.',10
    not_openedLen:  equ $-not_opened
    hello:      db  'Hello, this is written to a file'
    helloLen:   equ $-hello
    success:    db  'Successfully wrote to file.',10
    successLen: equ $-success

section .bss
    file:       resd    1

section .text
    global _start:

_start:
    pop ebx             ; pop number of params
    test ebx,2          ; make sure there are only 2
    jne bad_param_list
    pop ebx

    mov eax,4           ; write out opening file msg
    mov ebx,1
    mov ecx,opening
    mov edx,openingLen
    int 80h

    mov eax,5           ; open file
    pop ebx
    mov ecx,64 
    mov edx,777o            ; permissions of file
    int 80h
    mov dword [file],eax

    test dword [file],0
    jle bad_open

    mov eax,4           ; write successful open message
    mov ebx,1
    mov ecx,opened
    mov edx,openedLen
    int 80h

    mov ebx,file            ; write to file (4 already in eax)
    mov ecx,hello
    mov edx,helloLen
    int 80h

    mov eax,6           ; close file
    mov ebx,file
    int 80h

    mov eax,4           ; write successfully written msg
    mov ebx,1
    mov ecx,success
    mov edx,successLen
    int 80h

    mov eax,1           ; exit
    mov ebx,0
    int 80h

bad_param_list:
    mov eax,4           ; write that params are bad
    mov ebx,1
    mov ecx,bad_params
    mov edx,bad_paramsLen
    int 80h

    mov eax,1           ; exit with code 1
    mov ebx,1
    int 80h

bad_open:
    mov eax,4           ; write that we couldn't open the file
    mov ebx,1
    mov ecx,not_opened
    mov edx,not_openedLen
    int 80h

    mov eax,1           ; exit with code 2
    mov ebx,2
    int 80h

目标是将一串文本写入没有库函数的文件；我只使用 Linux 内核。我遇到了一些问题，比如到处缺少括号，以及所有其他错误，这些错误都是你从菜鸟到汇编所期望的，但我认为现在这基本上已经得到控制。

这是我的问题：据我所知，该程序的前四行应该将参数数量从堆栈中弹出，如果不仅有一个参数（除了程序名称），则跳转到 bad_param_list ，并将程序名称从堆栈中弹出。

但事实并非如此。下面是一些示例 I/O，为了清晰起见，重新格式化了：

$./writeFile
Opening file...
Unable to open file.  Halted.

$./writeFile x
Usage:  writeFile filename.ext

$./writeFile x x
Usage:  writeFile filename.ext

$./writeFile x x x
Opening file...
Unable to open file.  Halted.

$./writeFile x x x x
Opening file...
Unable to open file.  Halted.

$./writeFile x x x x x
Usage:  writeFile filename.ext

$./writeFile x x x x x x
Usage:  writeFile filename.ext

我注意到，如果您采用包括程序名称在内的参数数量，除以 2，并丢弃小数，如果答案是奇数，您将收到我的使用错误，但如果答案是偶数，您将收到无法打开错误。至少 10 个参数之前都是如此！

我到底是怎么做到这一点的？以及如何让它达到预期的结果？

Answer 1

不

test ebx,2

除了设置标志之外，您

cmp ebx,2

希望test 在参数之间执行按位 AND 并丢弃结果。因此，如果两个参数在匹配的位置上没有 1 位，则特别会设置 ZF。 （在您的特定情况下，这相当于将 ZF 设置为 ebx 的倒数第二位的补码）。

相反，cmp 减去其参数并在设置标志后丢弃结果。在这种情况下，如果两个参数相等，则将设置 ZF。