在 Haskell 中处理 UserInterrupt 异常

Question

我正在Haskell中为Scheme解释器实现REPL，我想处理一些异步事件，如UserInterrupt、StackOverflow、HeapOverflow等...基本上，我想在UserInterrupt发生时停止当前计算并打印当发生 StackOverflow 和 HeapOverflow 等时，会显示合适的消息。我的实现如下：

    repl evaluator = forever $ (do
        putStr ">>> " >> hFlush stdout
        out <- getLine >>= evaluator
        if null out
           then return ()
           else putStrLn out)
        `catch`
        onUserInterrupt

    onUserInterrupt UserInterrupt = putStrLn "\nUserInterruption"
    onUserInterrupt e = throw e

    main = do
        interpreter <- getMyLispInterpreter
        handle onAbort (repl $ interpreter "stdin")
        putStrLn "Exiting..."

    onAbort e = do
        let x = show (e :: SomeException)
        putStrLn $ "\nAborted: " ++ x

它按预期工作，但有一个例外。如果我启动解释器并按 Ctrl-Z + Enter，我会得到：

    >>> ^Z

    Aborted: <stdin>: hGetLine: end of file
    Exiting...

这是正确的。但是，如果我启动解释器并按 Ctrl-C，然后按 Ctrl-Z + Enter，我会得到：

    >>>
    UserInterruption
    >>> ^Z

它挂起，我无法再使用解释器。但是，如果我再次按 Ctrl-C，REPL 就会解除阻止。我搜索了很多，但无法弄清楚其中的原因。谁能给我解释一下吗？

非常感谢！

Answer 1

Control-C 处理不适用于 catch：可能与 GHC #2301：正确处理 SIGINT/SIGQUIT

这是一个工作测试用例，删除了评估器：

module Main where

import Prelude hiding (catch)

import Control.Exception ( SomeException(..),
                           AsyncException(..)
                         , catch, handle, throw)
import Control.Monad (forever)
import System.IO

repl :: IO ()
repl = forever $ (do
    putStr ">>> " >> hFlush stdout
    out <- getLine
    if null out
       then return ()
       else putStrLn out)
    `catch`
    onUserInterrupt

onUserInterrupt UserInterrupt = putStrLn "\nUserInterruption"
onUserInterrupt e = throw e

main = do
    handle onAbort repl
    putStrLn "Exiting..."

onAbort e = do
    let x = show (e :: SomeException)
    putStrLn $ "\nAborted: " ++ x

在 Linux 上，Control-Z 不会像 Sjoerd 提到的那样被捕获。也许您使用的是 Windows，其中 Control-Z 用于 EOF。我们可以使用 Control-D 在 Linux 上发出 EOF 信号，这会复制您所看到的行为：

>>> ^D
Aborted: <stdin>: hGetLine: end of file
Exiting...

EOF 由您的 handle/onAbort 函数处理，Control-C 由 catch/onUserInterrupt 处理代码>.这里的问题是您的 repl 函数只会捕获第一个 Control-C - 可以通过删除 handle/onAbort 函数来简化测试用例。如上所述，Control-C 处理不适用于 catch 可能与 GHC 有关#2301：正确处理 SIGINT/SIGQUIT。

以下版本使用 Posix API 为 Control-C 安装持久信号处理程序：

module Main where

import Prelude hiding (catch)

import Control.Exception ( SomeException(..),
                           AsyncException(..)
                         , catch, handle, throw)
import Control.Monad (forever)
import System.IO
import System.Posix.Signals

repl :: IO ()
repl = forever $ do
    putStr ">>> " >> hFlush stdout
    out <- getLine
    if null out
       then return ()
       else putStrLn out

reportSignal :: IO ()
reportSignal = putStrLn "\nkeyboardSignal"

main = do
    _ <- installHandler keyboardSignal (Catch reportSignal) Nothing
    handle onAbort repl
    putStrLn "Exiting..."

onAbort e = do
    let x = show (e :: SomeException)
    putStrLn $ "\nAborted: " ++ x

它可以处理多次按下 Control-C：

>>> ^C
keyboardSignal

>>> ^C
keyboardSignal

>>> ^C
keyboardSignal

如果不使用 Posix API，在 Windows 上安装持久信号处理程序需要重新引发异常每次捕获时，如 http://suacommunity.com/dictionary/signals.php 中所述