向宏添加可选参数

Question

我正在尝试向 Clojure 时间宏添加一个选项“message”属性。基本上我想向时间输出添加可选的自定义消息。我试图找到程序中的瓶颈，并且在时间输出中附加一些描述性消息将非常有帮助。

我已经尝试过以下操作：

;optional argument
(defmacro time
  "Evaluates expr and prints the time it took.  Returns the value of
 expr."
  {:added "1.0"}
  [expr & msg]
  `(let [start# (. System (nanoTime))
         ret# ~expr]
     (prn (str "Elapsed time: " (/ (double (- (. System (nanoTime)) start#)) 1000000.0) " msecs. " (first ~msg)))
     ret#))

并且

(defmacro time
  "Evaluates expr and prints the time it took.  Returns the value of
 expr."
  {:added "1.0"}
  ([expr] (time expr ""))
  ([expr msg]
  `(let [start# (. System (nanoTime))
         ret# ~expr]
     (prn (str "Elapsed time: " (/ (double (- (. System (nanoTime)) start#)) 1000000.0) " msecs. " ~msg))
     ret#)))

两者都抛出异常。我该如何进行这项工作？

Answer 1

它会引发异常，因为 msg 是一个列表，

假设您使用宏调用它，

(time (+ 1 1) "asd")

宏中的 msg 变成函数调用（“asd”），该函数调用失败。只需解构 msg，

 [expr & [msg]]

然后使用

 ~msg

您还可以测试如何使用 Macroexpand 扩展宏，

(macroexpand '(time (+ 1 1) "asd"))

还有几点，

• 时间已经在核心中，
• 您的版本仅接受单个表达式并对其进行计时。

编辑：带有可选消息的时间，

(defmacro time
  "Evaluates expr and prints the time it took.  Returns the value of
 expr."
  {:added "1.0"}
  [expr & [msg]]
  (let [msg (if (nil? msg) "" msg)]
    `(let [start# (. System (nanoTime))
         ret# ~expr]
       (prn (str "Elapsed time: " (/ (double (- (. System (nanoTime)) start#)) 1000000.0) " msecs. " ~msg))
       ret#)))

(time (+ 1 1))
"Elapsed time: 0.068 msecs. "
2

(time (+ 1 1) "asd")
"Elapsed time: 0.067 msecs. asd"
2