Seq.Map string->string

Question

全部！

这段代码有什么问题？我无法理解我对 Seq.Map 做错了什么。 这是错误消息：类型“unit”与类型“seq<'a>'不兼容”

let getPathToLibFile value =
    let regex = new Regex("\"(?<data>[^<]*)\"")
    let matches = regex.Match(value)
    matches.Value

let importAllLibs (lines:string[]) =
    lines
    |> Seq.filter isImportLine
    |> Seq.iter (printfn "Libs found: %s")
    |> Seq.map getPathToLibFile // error in this line
    |> Seq.iter (printfn "Path to libs: %s")

Seq.Map上有什么可以理解的例子吗？

来自 wiki 的 PS 示例（有效）：

(* Fibonacci Number formula *)
let rec fib n =
    match n with
    | 0 | 1 -> n
    | _ -> fib (n - 1) + fib (n - 2)

(* Print even fibs *)
[1 .. 10]
|> List.map     fib
|> List.filter  (fun n -> (n % 2) = 0)
|> printlist

Answer 1

我怀疑问题实际上是您之前的通话造成的。

Seq.iter 不返回任何内容（或者更确切地说，返回unit），因此您不能在管道中间使用它。试试这个：

let importAllLibs (lines:string[]) =
    lines
    |> Seq.filter isImportLine
    |> Seq.map getPathToLibFile
    |> Seq.iter (printfn "Path to libs: %s")

...然后，如果您确实需要打印出“找到的库”行，您可以添加另一个执行打印并仅返回输入的映射：

let reportLib value =
    printfn "Libs found: %s" value
    value

let importAllLibs (lines:string[]) =
    lines
    |> Seq.filter isImportLine
    |> Seq.map reportLib
    |> Seq.map getPathToLibFile
    |> Seq.iter (printfn "Path to libs: %s")

这很可能是无效的 F#，但我认为 目标是正确的:)

Answer 2

WebSharper 包含一个您可以自己定义的运算符，如下所示：

let (|!>) a f = f a; a

允许您调用 'a ->; 类型的函数返回相同值的输入值上的单位。

修复你的代码只需要稍微修改一下：

lines
|> Seq.filter isImportLine
|!> Seq.iter (printfn "Libs found: %s")
|> Seq.map getPathToLibFile // error in this line
|> Seq.iter (printfn "Path to libs: %s")

另一方面，你最终会迭代集合两次，这可能不是你想要的。

更好的方法是定义一个函数 Do（小写 do 是 F# 中的保留关键字），它会在迭代序列时产生副作用。 Rx.NET (Ix) 在 EnumerableEx 中提供了这样的函数：

let Do f xs = Seq.map (fun v -> f v; v) xs

然后你可以像这样引入副作用：

lines
|> Seq.filter isImportLine
|> Do (printfn "Libs found: %s")
|> Seq.map getPathToLibFile // error in this line
|> Seq.iter (printfn "Path to libs: %s")

只有在迭代最后一行的集合时才会引入副作用。