如何处理 Perl 中方法链中的错误？

Question

处理 Perl 中方法链接中抛出的异常的最佳方法是什么？ 如果任何链接的方法抛出异常，我想分配 0 或 undef 值

代码示例：

my $x = $obj->get_obj->get_other_obj->get_another_obj->do_something;

最好的方法是什么？ 我每次都必须用 try/catch/finally 语句换行吗？ 我想要应用这个的上下文是：我使用 Catalyst 和 DBIC 进行 Web 开发，并且我做了很多链接的结果集，如果其中一些结果集抛出异常，我只想分配一个值 0 或 undef，然后处理它模板中的错误（我正在使用模板工具包）。如果有另一种方法可以做到这一点，而不用将每个调用包装在 try/catch 中，请告诉我。如果您知道在相同上下文（Catalyst/DBIC/TT）中处理此类错误的更好方法，请提出建议。 一个实际的例子是，当用户搜索某物但该物不存在时。

Answer 1

我通过在失败时返回一个空对象来处理这个问题。该对象通过简单地返回自身来响应每个方法，因此它会继续这样做，直到耗尽剩余的方法。最后，您查看 $x 看看它是您期望的结果还是这个 null 对象。

下面是这样的一个例子：

use v5.12;

package Null {
    my $null = bless {}, __PACKAGE__;
    sub DESTROY { 1 }
    sub AUTOLOAD { $null }
    }

对于每个调用的方法，AUTOLOAD 都会拦截它并返回空对象。

当您遇到错误时，您将返回这些 Null 对象之一。在方法链的中间，您仍然会返回一个对象，这样当您调用下一个方法时，Perl 就不会崩溃。

sub get_other_obj {
    ...;
    return Null->new if $error;
    ...;
    }

在链的末尾，您可以检查返回的内容以查看它是否为 Null 对象。如果这就是你得到的，那么就发生了不好的事情。

这就是基本的想法。您可以改进 Null 类，使其记住消息及其创建位置，或者添加一些多态方法（例如 sub is_success { 0 }），使其能够与你期望得到的物品。

我以为我在某处写过很长的文章，但现在我找不到了。

更新：找到了其中一些著作：

• The Null Mull
• 没有如果、和或但是

Answer 2

您可以编写一个标量方法，该方法将在错误处理中包装方法链：

my $try = sub {
    @_ > 1 or return bless {ok => $_[0]} => 'Try';

    my ($self, $method) = splice @_, 0, 2;
    my $ret;
    eval {
        $ret = $self->$method(@_);
    1} or return bless {error => $@} => 'Try';
    bless {ok => $ret} => 'Try'
};

{package Try;
    use overload fallback => 1, '""' => sub {$_[0]{ok}};
    sub AUTOLOAD {
        my ($method) = our $AUTOLOAD =~ /([^:]+)$/;
        $_[0]{ok} ? $_[0]{ok}->$try($method, @_[1..$#_]) : $_[0]
    }
    sub DESTROY {}
    sub error {$_[0]{error}}
}

使用它：

{package Obj;
    sub new {bless [0]}
    sub set {$_[0][0] = $_[1]; $_[0]}
    sub add {$_[0][0] += ($_[1] || 1); $_[0]}
    sub show {print "Obj: $_[0][0]\n"}
    sub dies  {die "an error occured"}
}

my $obj = Obj->new;

say "ok 1" if $obj->$try(set => 5)->add->add->show; # prints "Obj 7"
                                                    # and "ok 1"

say "ok 2" if $obj->$try('dies')->add->add->show;   # prints nothing 

say $obj->$try('dies')->add->add->show->error;  # prints "an error occured..."

$try 方法的第一行还允许使用以下语法：

say "ok 3" if $obj->$try->set(5)->add->add->show;

Answer 3

一种想法是创建一个类，使用 overload 在实例对象在字符串/数字/布尔上下文中进行评估，但仍然允许对其调用方法。 AUTOLOAD 方法始终可以返回 $self，从而允许方法链传播相同的错误。