如何将浮点数或货币转换为本地化字符串？

Question

在Delphi¹中，使用FloatToStrF或CurrToStrF将自动使用DecimalSeparator字符来表示小数点。不幸的是 DecimalSeparator 在 SysUtils 中声明为 Char< /code>1,2：

var 
  DecimalSeparator: Char;

而 LOCALE_SDECIMAL 是最多允许三个字符：

用于小数点分隔符的字符，例如“.”在“3.14”或“3,14”中的“,”。该字符串允许的最大字符数为四个，包括终止空字符。

这会导致Delphi无法正确读取小数点分隔符；回退到默认的小数点分隔符“.”：

DecimalSeparator := GetLocaleChar(DefaultLCID, LOCALE_SDECIMAL, '.');

在我的计算机上，这是一个相当大的字符，这会导致浮点和货币值被错误地本地化为U+002E（句号）小数点。

我愿意直接调用 Windows API 函数，这些函数旨在将浮点或货币值转换为本地化字符串：

• GetNumberFormat
• GetCurrencyFormat

除外这些函数采用一串图片代码，其中唯一允许的字符是：

• 字符“0”到“9” (U+0030..U+0039)
• 如果数字是浮点值 ()，则保留一位小数点 (.) U+002E)
• 如果数字是负值，则在第一个字符位置添加减号 (U+002D)

什么是一个好方法¹将浮点或货币值转换为遵守这些规则的字符串？例如

• 1234567.893332
• -1234567

鉴于本地用户的区域设置（即我的计算机）：

• 可能不会使用 - 来表示否定（例如 --)
• 可能不使用 。指示小数点（例如,,）
• 可能不会使用拉丁字母 0123456789 来表示数字（例如[删除了导致崩溃的阿拉伯数字javascript解析器]）

---

一个可怕的，可怕的黑客，我可以使用：

function FloatToLocaleIndependantString(const v: Extended): string;
var
   oldDecimalSeparator: Char;
begin
   oldDecimalSeparator := SysUtils.DecimalSeparator;
   SysUtils.DecimalSeparator := '.'; //Windows formatting functions assume single decimal point
   try
      Result := FloatToStrF(Value, ffFixed, 
            18, //Precision: "should be 18 or less for values of type Extended"
            9 //Scale 0..18.   Sure...9 digits before decimal mark, 9 digits after. Why not
      );
   finally
      SysUtils.DecimalSeparator := oldDecimalSeparator;
   end;
end;

---

关于VCL使用的函数链的附加信息：

• FloatToStrF 和 CurrToStrF 调用：
  • FloatToText 调用：
    • FloatToDecimal

注意< /strong>

• DecimalSeparator: Char，单个 字符全局已弃用，并替换为另一个单字符小数分隔符

¹ 在我的 Delphi 版本中
² 以及当前版本的 Delphi

Answer 1

Delphi 确实提供了一个名为FloatToDecimal 的过程，它将浮点（例如扩展）和Currency 值转换为有用的结构以供进一步格式化。例如：

FloatToDecimal(..., 1234567890.1234, ...);

给出：

TFloatRec
   Digits: array[0..20] of Char = "12345678901234"
   Exponent: SmallInt =           10
   IsNegative: Boolean =          True

其中 Exponent 给出小数点左侧的位数。

有一些特殊情况需要处理：

• 指数为零

   数字：Char 的数组[0..20] = "12345678901234"
     指数：SmallInt = 0
     是否负：布尔值 = True
  

  表示小数点左边没有数字，例如.12345678901234

• 指数为负

   数字：Char 的数组[0..20] = "12345678901234"
     指数：SmallInt = -3
     是否负：布尔值 = True
  

  表示您必须在小数点和第一位数字之间添加零，例如 .00012345678901234

• 指数为 -32768 （NaN，不是数字）

   数字：Char 的数组[0..20] = ""
     指数：SmallInt = -32768
     IsNegative：布尔值 = False
  

  表示该值不是数字，例如 NAN

• 指数为 32767（INF 或 -INF）

   数字：Char 的数组[0..20] = ""
     指数：SmallInt = 32767
     IsNegative：布尔值 = False
  

  表示该值为正无穷大或负无穷大（取决于IsNegative值），例如-INF

---

我们可以使用FloatToDecimal作为起点来创建与区域设置无关的“图片代码”字符串。

然后可以将此字符串传递给适当的 Windows GetNumberFormat 或 GetCurrencyFormat 函数以执行实际的正确本地化。

我编写了自己的 CurrToDecimalString 和 FloatToDecimalString ，它们将数字转换为所需的独立于语言环境的格式：

class function TGlobalization.CurrToDecimalString(const Value: Currency): string;
var
    digits: string;
    s: string;
    floatRec: TFloatRec;
begin
    FloatToDecimal({var}floatRec, Value, fvCurrency, 0{ignored for currency types}, 9999);

    //convert the array of char into an easy to access string
    digits := PChar(Addr(floatRec.Digits[0]));

    if floatRec.Exponent > 0 then
    begin
        //Check for positive or negative infinity (exponent = 32767)
        if floatRec.Exponent = 32767 then //David Heffernan says that currency can never be infinity. Even though i can't test it, i can at least try to handle it
        begin
            if floatRec.Negative = False then
                Result := 'INF'
            else
                Result := '-INF';
            Exit;
        end;

        {
            digits:    1234567 89
              exponent--------^ 7=7 digits on left of decimal mark
        }
        s := Copy(digits, 1, floatRec.Exponent);

        {
            for the value 10000:
                digits:   "1"
                exponent: 5
            Add enough zero's to digits to pad it out to exponent digits
        }
        if Length(s) < floatRec.Exponent then
            s := s+StringOfChar('0', floatRec.Exponent-Length(s));

        if Length(digits) > floatRec.Exponent then
            s := s+'.'+Copy(digits, floatRec.Exponent+1, 20);
    end
    else if floatRec.Exponent < 0 then
    begin
        //check for NaN (Exponent = -32768)
        if floatRec.Exponent = -32768 then  //David Heffernan says that currency can never be NotANumber. Even though i can't test it, i can at least try to handle it
        begin
            Result := 'NAN';
            Exit;
        end;

        {
            digits:   .000123456789
                         ^---------exponent
        }

        //Add zero, or more, "0"'s to the left
        s := '0.'+StringOfChar('0', -floatRec.Exponent)+digits;
    end
    else
    begin
        {
            Exponent is zero.

            digits:     .123456789
                            ^
        }
        if length(digits) > 0 then
            s := '0.'+digits
        else
            s := '0';
    end;

    if floatRec.Negative then
        s := '-'+s;

    Result := s;
end;

除了 NAN、INF 的边缘情况之外 和 -INF，我现在可以将这些字符串传递到 Windows：

class function TGlobalization.GetCurrencyFormat(const DecimalString: WideString; const Locale: LCID): WideString;
var
    cch: Integer;
    ValueStr: WideString;
begin
    Locale
        LOCALE_INVARIANT
        LOCALE_USER_DEFAULT     <--- use this one (windows.pas)
        LOCALE_SYSTEM_DEFAULT
        LOCALE_CUSTOM_DEFAULT       (Vista and later)
        LOCALE_CUSTOM_UI_DEFAULT    (Vista and later)
        LOCALE_CUSTOM_UNSPECIFIED   (Vista and later)
}

    cch := Windows.GetCurrencyFormatW(Locale, 0, PWideChar(DecimalString), nil, nil, 0);
    if cch = 0 then
        RaiseLastWin32Error;

    SetLength(ValueStr, cch);
    cch := Windows.GetCurrencyFormatW(Locale, 0, PWideChar(DecimalString), nil, PWideChar(ValueStr), Length(ValueStr));
    if (cch = 0) then
        RaiseLastWin32Error;

    SetLength(ValueStr, cch-1); //they include the null terminator  /facepalm
    Result := ValueStr;
end;

FloatToDecimalString 和 GetNumberFormat 实现留给读者作为练习（因为我实际上还没有编写浮点数，只是货币 - 我不知道）不知道我将如何处理指数表示法）。

还有鲍勃的叔叔； Delphi 下正确本地化的浮动和货币。

我已经完成了正确本地化整数、日期、时间和日期时间的工作。

注意：任何代码都会发布到公共领域。无需归属。

Answer 2

好吧，这可能不是您想要的，但它适用于 D2007 及更高版本。
线程安全等等。

uses Windows,SysUtils;

var
  myGlobalFormatSettings : TFormatSettings;

// Initialize special format settings record
GetLocaleFormatSettings( 0,myGlobalFormatSettings);
myGlobalFormatSettings.DecimalSeparator := '.';


function FloatToLocaleIndependantString(const value: Extended): string;
begin
  Result := FloatToStrF(Value, ffFixed, 
        18, //Precision: "should be 18 or less for values of type Extended"
        9, //Scale 0..18.   Sure...9 digits before decimal mark, 9 digits after. Why not
        myGlobalFormatSettings
  );
end;