从多行单元格列生成列表

Question

我有一个表，其中一列是项目的属性。一个项目可以有许多属性，所有这些属性都存储在每个项目的一个单元格中，以单独的文本行形式存储。我想制作包含迄今为止我使用过的所有属性类型的脚本，并将该列表保存在第二张表中。它可能无法通过标准公式实现，因此我假设需要使用VBA。我以前从未使用过VBA，不知道如何完成这项任务。我也找不到这种语言的任何参考。我正在使用 MS Office 2007。

Answer 1

Sub export()
Dim cell As Range
Dim i As Long, j As Long
Dim var() As String
j = 1
For Each cell In Sheets(1).Range("a1:a10")
    Var = Split(cell, vbLf)
        For i = 0 To UBound(Var)
            Sheets(2).Range("a" & j).Value = Var(i)
            j = j + 1
        Next i    
Next cell
End Sub

我的示例循环sheet1 的a1:a10 范围内的所有单元格。根据您的需求进行调整。
每个单元格都按换行符拆分，并将每一行复制到第二个工作表中。

Answer 2

这是 @nick Rulez 的精彩答案的修改版本，它使用字典对象，允许您排除所有重复项。

Sub export()

Dim cell As range
Dim i As Long, j As Long
Dim var As Variant
Dim dictionary As Object
Set dictionary = CreateObject("scripting.dictionary")

On Error Resume Next
j = 1
For Each cell In Sheets(1).range("a1:a10")
    var = Split(cell, vbLf)
    For i = 0 To UBound(var)
        dictionary.Add var(i), 1
        j = j + 1
    Next i
Next

Sheet2.range("A1").Resize(dictionary.count).Value = _
Application.Transpose(dictionary.keys)

End Sub

工作原理：它与 nick 的功能相同，但不是将每个拆分条目写入sheet2，而是将条目添加到字典文件中。由于字典不允许有 2 个具有相同值的键，因此它会跳过重复项（不过，在接下来的错误恢复中您需要重复重复项）。 Dictionary 具有超酷的调换键数组的能力，所以最后，我只需一步复制整个列表即可。