在 perl 中是否有简单的语法来声明具有一个值的多个键？

Question

有没有一种简单的方法来声明具有多个键的散列，这些键都指向 perl 中的相同值？

这是与我正在寻找的类似的东西（我实际上不知道这是否有效）：

my $hash = {
             a, b, c => $valA,
             d, e, f => $valB
           };

这样......

print $hash->{a}; #prints $valA
print $hash->{b}; #prints $valA
print $hash->{c}; #prints $valA
print $hash->{d}; #prints $valB
print $hash->{e}; #prints $valB
print $hash->{f}; #prints $valB

Answer 1

你可以这样写：

my %hash;
$hash{$_} = $valA for qw(a b c);
$hash{$_} = $valB for qw(d e f);

Answer 2

不，没有简单的语法。 （实际上，=> 被记录为 , 的别名，其唯一的正式效果是即使在严格模式下，它也允许在其左侧出现裸字）。

在不定义自己的潜艇的情况下，你可以做的最好的事情可能是这样的

@hash{qw(a b c)} = ($valA) x 3 ;
@hash(qw(d e f)} = ($valB) x 3 ;

Answer 3

我喜欢在一侧使用哈希片，在另一侧使用列表复制运算符。我使用键数组的标量值来计算要复制的值的数量：

 @hash{ @keys } = ($value) x @keys;

Answer 4

没有内置语法，但您始终可以编写自己的语法：

my $value = sub {map {$_ => $_[1]} @{$_[0]}};

my $hash = {
    [qw(a b c)]->$value('valA'),
    [qw(d e f)]->$value('valB'),
};

say join ', ' => map "$_: $hash{$_}", sort keys %$hash;
# a: valA, b: valA, c: valA, d: valB, e: valB, f: valB

如果您要经常这样做，您可能需要查看 Hash::Util 的 hv_store< /code> 函数，它允许您加载具有完全相同的内存位置的多个密钥。

Answer 5

您可以使用哈希切片分配：

my $hash = {};

@$hash{a,b,c} = ($valA) x 3;
@$hash{d,e,f} = ($valB) x 3;

Answer 6

也可以使用语句来完成赋值，例如使用map。在这里，map 将扩展为两个列表。

my $hash = {
    ( map { $_ => $valA } ('a' .. 'c') ),
    ( map { $_ => $valB } ('d' .. 'f') ),
};

Answer 7

是的，正如 Henning Makholm 指出的那样，没有直接的快捷方式，因为 => 是 , 的别名。我能想到的最接近快捷方式的是：

foreach('a','b','c')
{
  $hash->{$_}=$valA;
}

foreach('d','e','f')
{
  $hash->{$_}=$valB;
}