Mathematica 表格集

Question

我有三个表X,Y,Z。而X & Y 定义我的网格点，Z 取决于 X 和 Y 的每个点。

x = Table[i, {i, 0, 10, 1}]
y = Table[j, {j, 0, 10, 1}]
z = Table[5*i + j, {i, 0, 10, 1}, {j, 0, 10, 1}]

现在我希望最终列表看起来像这样 [{x1,y1,z1},{x2,y2,z2}}

我想创建一组相应的 x,y,z 上面给出的表中的值。

Answer 1

在这种情况下，您还可以使用 Array 如下：

Array[{##, 5 # + #2} &, {11, 11}, 0]

参见 Function 和 插槽。 rcollyer 已经展示了如何从中“拆分”x、y 和 z。

当从不相关的列表 x 和 y 开始时，您可以使用 外部：

Outer[{##, 5 # + #2} &, x, y, 1]

Answer 2

除非您需要 x 和 y 列表，否则我会将其组合在一个 Table 中，如下所示：

Table[{i, j, 5*i + j}, {i, 0, 10}, {j, 0, 10}]

注意，我删除了步长（ {i, 0, 10, 1} -> {i, 0, 10})，因为如果不包含它，它会隐式设置为 1。

编辑：如果您还希望拥有 x 和 y 列表，您可以执行以下操作

Table[{i, j, 5*i+j}, {i, x}, {j, y}]

从 v.7 开始，Table 除了起点和终点之外还接受值列表。这并没有解决您是否还需要单独的 z 列表。在这种情况下，我将从第一个形式的代码开始，并使用 Transpose （根据您的其他 问题）设置各个列表，如下所示：

coords = Table[{i, j, 5*i + j}, {i, 0, 10}, {j, 0, 10}];
{x, y, z} = Transpose @ coords;

Answer 3

从你开始的一种方法

x = Table[i, {i, 0, 10, 1}];
y = Table[j, {j, 0, 10, 1}];
z = Table[5*i + j, {i, 0, 10, 1}, {j, 0, 10, 1}];

是

Flatten[
    MapThread[{Sequence @@ #1, #2} &,
        {Outer[{#1, #2} &, x, y], z},
        2
    ],
    1
]

（我很乐意看到我在一周内尝试理解这一点），它给出了你想要的东西。

这也有效：

p = {};
Do[
    Do[
        AppendTo[p, {x[[i]], y[[j]], z[[i, j]]}],
        {j, 1, Length@y}
    ],
    {i, 1, Length@x}
]

并给出相同的答案。