如何防止在 Vim 中遍历跳转列表时离开当前缓冲区？

Question

我经常在 Vim 会话中打开多个缓冲区。这意味着我的跳转列表存储来自多个缓冲区的位置。但是，经常当我使用 Ctrl+O 键盘快捷键跳转到上一个位置时，我不想离开缓冲区并想跳转到上一个位置“本地”到当前缓冲区。我该怎么做？

例如，假设我的跳转列表如下所示：

4   10   1 ~/aaa.m
3   20   1 ~/aaa.m
2   12   2 ~/xxx.m
1   15   1 ~/aaa.m

我想在第一次按 Ctrl+O< 时跳转到文件 aaa.m 的第 15 行/kbd>。重要的是，下次我按 Ctrl+O 时，我不想跳转到文件xxx.m。相反，我想跳转到文件aaa.m的第20行，即我在“当前”缓冲区中的先前位置。不过，默认的 Vim 行为是转到文件xxx.m 的第 12 行。

关于如何实现这一目标有什么想法吗？

Answer 1

尝试下面的跳转列表遍历函数。它一步一步地
从一个跳转列表位置到另一个位置（使用 Ctrl+O
或 Ctrl+I 取决于值
提供给其 back 和 forw 参数），如果当前
位置与其起始缓冲区位于同一缓冲区中。
如果无法找到属于
当前缓冲区，函数返回跳转列表中的位置
这是调用该函数之前的当前值。

function! JumpWithinFile(back, forw)
    let [n, i] = [bufnr('%'), 1]
    let p = [n] + getpos('.')[1:]
    sil! exe 'norm!1' . a:forw
    while 1
        let p1 = [bufnr('%')] + getpos('.')[1:]
        if n == p1[0] | break | endif
        if p == p1
            sil! exe 'norm!' . (i-1) . a:back
            break
        endif
        let [p, i] = [p1, i+1]
        sil! exe 'norm!1' . a:forw
    endwhile
endfunction

将此函数用作
Ctrl+O/Ctrl+I - 替换
锁定到当前缓冲区，创建映射，如下所示。

nnoremap <silent> <c-k> :call JumpWithinFile("\<c-i>", "\<c-o>")<cr>
nnoremap <silent> <c-j> :call JumpWithinFile("\<c-o>", "\<c-i>")<cr>

Answer 2

也许 EnhancedJumps 插件会有所帮助。

安装此插件后，仅当随后立即再次重复相同的跳转命令时，才会跳转到另一个缓冲区。