VBScript 在不运行 Outlook 的情况下发送电子邮件

Question

我编写了一个每晚运行的自动化测试，我想在测试完成后每晚通过电子邮件发送结果。

为了做到这一点，我尝试将以下内容放在批处理文件的末尾：

Set MyApp = CreateObject("Outlook.Application")
Set MyItem = MyApp.CreateItem(0)
With MyItem
    .To = "[email protected]"
    .Subject = "Subject"
    .ReadReceiptRequested = False
    .HTMLBody = "resport"
End With
MyItem.Send

但是，这会导致电子邮件无法发送，因为我的 Outlook 未打开，因为测试在后台运行，并且我无权访问用户界面。

无论如何，是否可以在不实际在计算机上运行 Outlook 的情况下发送此电子邮件。

谢谢！

Answer 1

您可以在 VBScript 中使用 CDO.Message 对象在没有 Outlook 的情况下发送电子邮件。您需要知道 SMTP 服务器的地址才能使用此地址：

Set MyEmail=CreateObject("CDO.Message")

MyEmail.Subject="Subject"
MyEmail.From="[email protected]"
MyEmail.To="[email protected]"
MyEmail.TextBody="Testing one two three."

MyEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing")=2

'SMTP Server
MyEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver")="smtp.server.com"

'SMTP Port
MyEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport")=25 

MyEmail.Configuration.Fields.Update
MyEmail.Send

set MyEmail=nothing

如果您的 SMTP 服务器需要用户名和密码，请将这些行粘贴到 MyEmail.Configuration.Fields.Update 行上方：

'SMTP Auth (For Windows Auth set this to 2)
MyEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate")=1
'Username
MyEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername")="username" 
'Password
MyEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword")="password"

更多信息使用 CDO 通过 VBScript 发送电子邮件可以在下面的链接中找到：
http://www.paulsadowski.com/wsh/cdo.htm

Answer 2

这是您从其他服务（例如私人电子邮件）发送电子邮件的方式

Set objMessage = CreateObject("CDO.Message") 
 objMessage.Subject = "Wooow" 
 objMessage.From = "[email protected]" 
 objMessage.To = "[email protected]" 
 objMessage.TextBody = "You are awesome"
 Set objConfig = objMessage.Configuration
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "serverXXXXXX.web-hosting.com"
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "[email protected]"
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "YOUR_PASSWORD_XXXX"
 'Server port (typically 25)
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 4XX
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = true
 objConfig.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
 objConfig.Fields.Update
 objMessage.Send

我测试了它，它有效。

Answer 3

是的。 Blat 或任何其他独立的 SMTP 邮件程序。 Blat 是一个功能相当齐全的 SMTP 客户端，从命令行运行

Blat 在这里

Answer 4

以下是架构文档的当前链接：

https://learn.microsoft.com/en-us/previous-versions/office/developer/exchange-server-2003/ms873029(v=exchg.65)

而不是使用对象引用再说一次，一个漂亮的 With 语句看起来会更好：

Set Msg = CreateObject("CDO.Message")
With Msg
 .To = "[email protected]"
 .From = "[email protected]"
 .Subject = "Subject goes here."
 .TextBody = "Message goes here."
End With
With Msg.Configuration
 .Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
 .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "mail.example.com"
 .Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
 .Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = "username"
 .Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "password"
 .Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587
 .Fields("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = false
 .Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 15
 .Fields.Update
End With
Msg.Send

关于 smtpusessl 字段的额外说明：这仅适用于 TLS 类型端口。它与 STARTTLS 协议不同。使用 STARTTLS 时只需将其设置为 false 即可。