ColdFusion 循环遍历列表的[仅部分]

Question

真的很难找到一种方法来循环冷融合列表的一部分（或者一半？）。我设置了一个 if 语句来检查列表的长度以及是否超过 30...我想将列表拆分为前 30 个和其余部分？但不确定这是否是最好的解决方案。我真的不需要太多细节，我相信我自己能弄清楚这么多，我更希望被指出正确的方向......

Answer 1

不要循环列表，而是从 1 循环到数字，并在循环中使用 listGetAt()。对于列表的其余部分，只需从#myvar + 1# 循环到#listLen#。

<cfoutput>
    <cfloop from="1" to="#myVar#" index="idx">
        #listGetAt( myList, idx )#<br />
    </cfloop>
</cfoutput>

当然，这不是最有效的方法。如果遇到性能问题，可能需要通过 listToArray() 将列表转换为数组，然后执行以下操作：

<cfset myArray = listToArray( myList ) />

<cfoutput>
    <cfloop from="1" to="#myVar#" index="idx">
        #myArray[ idx ]#<br />
    </cfloop>
</cfoutput>

Answer 2

您可以利用底层的 java 函数。

<cfscript>
testList = "1,2,3,4,5,6,7,8,9,10,...,43,44";
listAsArray = listToArray(testList);
testChunk = listAsArray.subList(0,30);
</cfscript>

将为您提供一个数组“testChunk”，其中包含列表中的前 30 个项目。您现在可以轻松地循环数组的元素。

为了更清楚地说明这一点，下面是一个示例：

<cfscript>
    testList = "";
    maxChunkLength = 30;
    for (i=1;i lte 100; i=i+1){
        testList = listAppend(testList, i);
    }
    numOfChunks = ceiling(listLen(testList)/maxChunkLength);
    listAsArray = listToArray(testList);
    numOfItems = arraylen(listAsArray);
    for (k=1;k lte numOfChunks; k=k+1){
        startItem = (k - 1) * maxChunkLength;
        endItem = startItem + maxChunkLength;
        if (endItem gt numOfItems){
            endItem = numOfItems;
        } 
        writeOutput(listAsArray.subList(startItem, endItem).toString() & "<br />");
    }
</cfscript>

Answer 3

这实际上取决于您想要完成的任务、如何使用这两个独立的数据集以及列表中的数据类型......数据真的需要分离吗？你可以吗：

<cfloop from="31" to="#listLen(myList)#" index="i">
      #listGetAt(myList, i)#
</cfloop>

如果你不需要采取额外的步骤来分成两个列表或数组，那么就可以节省一些编码和工作量。执行时间

另外 - 如果您的起点发生变化，您始终可以：

<cfloop from="#start#" to="#listLen(myList)#" index="i">
     #listGetAt(myList, i)#
</cfloop>

-sean

Answer 4

在 CF10 或 Railo 4 中，您可以使用 first() 和 rest() 函数来自 Underscore.cfc 来拆分您的列表：

_ = new Underscore();

myArray = listToArray(myList);

firstThirty = _.first(myArray, 30);
remaining = _.rest(myArray, 31);

_.first() 和 _.rest() 都根据传递给它们的索引返回新数组。这些方法只是委托给本机 arraySlice() 函数，但它们可以帮助您编写更具表现力的代码。

注：我写的是Underscore.cfc