使用 File::Path 创建目录，但所有者和组设置不正确

Question

我正在尝试编写一个小的 Perl 脚本来创建目录结构。为了创建目录，我使用标准模块 File::Path，如下所示：

make_path($directory,
    {
        owner   => 'apache',
        group   => 'apache',
        mode    => 0500
    }
);

执行脚本时，将根据需要创建目录并按预期设置 umask，但文件的所有者和组都是“root”。这是错误的，但是错误在哪里呢？错误参数不会打印或给出任何错误消息。

预先感谢，

乔斯特

Answer 1

我刚刚尝试了一下，得到了和你一样的结果。我查看了文档：

perldoc File::Path

...并且没有提及“所有者”选项。然而，搜索最新版本（2.08，AFAICT）文档，它就在那里。您可以检查系统上模块的版本吗？

perl -MFile::Path -e 'print $File::Path::VERSION'

如果您运行的不是 2.08，这可能就是问题所在。我现在正在尝试追踪模块的变更日志，但是遇到困难...

[稍后]

好的，这就是您想要做的：

#!/usr/bin/perl -w

use strict;

use File::Path qw( make_path );

my $directory = $ARGV[0];
my $owner = 33;

make_path( $directory, { mode => 0500 } );
chown 33, 33, $directory;

最终，最后一行是您想要记下的一行。当您使用该版本的 File::Path 创建该文件时，无法设置所有者，但可以更改它。我的示例中的 33 是​​我系统上 www-data 用户的 UID；显然，您希望将 33 更改为对您的系统更合理的值。此外，您还需要确保您的脚本以能够执行此操作的权限运行。例如，如果您以低级用户身份运行它，它将不起作用，但如果您以 root 身份运行它，则 chown 将起作用。您可能想在那里找到一些中间立场。

Answer 2

我认为这是 File::Path 中的一个错误；它会悄悄地忽略它无法识别的键。

#!/usr/bin/perl

use strict;
use warnings;

use File::Path;

print "Using File::Path version $File::Path::VERSION with Perl $]\n";

my $tmpdir = "/tmp/file-path-test-$";

print "Creating $tmpdir\n";
mkdir $tmpdir, 0777 or die "$tmpdir: $!\n";

my @result = File::Path::make_path
                ( "$tmpdir/new-dir",
                  { owner => 'kst',
                    mode => 0500,
                    nosuchkey => 'WTF?' } );

print "Created ( @result )\n";

（请注意，这假设您的系统上有一个名为“kst”的帐户；根据您的系统需要进行调整。）

当我使用 File::Path 版本 2.07_03 和 Perl 5.010001 在 sudo 下运行此命令时，创建的目录由root拥有；当我做完全相同的事情，但使用 File::Path 版本 2.08_01 和 Perl 5.014000 时，该目录由 kst 所有。无论哪种情况，都没有迹象表明无法识别的密钥存在问题（旧版本的 owner 和 nosuchkey，新版本的只是 nosuchkey ）。

perldoc File::Path 没有解决这个问题（除非我错过了），并且我没有看到程序有任何干净的方法来确定 File::Path code> 它使用的可以处理较新的选项。 （您可以检查 $File::Path:VERSION，但这需要知道何时实施新选项。）

我刚刚 报告了此问题。

Answer 3

仅当您想创建单个目录而不是更多嵌套目录时，肯尼的回答才有用 - 例如。 make_path('foo/bar');
在第二种情况下，只有最后一个目录的所有者/组将被更改。

更正确的方法可以是这样的：

#!/usr/bin/perl -w

use strict;

use File::Path qw( make_path );
use File::Spec;

my $directory = $ARGV[0];
my $gid = getgrnam( "my_group" );
my $uid = getpwnam( "my_user" );

make_path( $directory, { mode => 0750 } );
my @directories = File::Spec->splitdir( $directory );
my @path;
foreach my $dir ( @directories ) {
    push( @path, $dir );
    chown $uid, $gid, File::Spec->catdir( @path );
}