高阶函数内的多态性？

Question

我有一个代数数据类型，其中一些构造函数保存可比较的值，而另一些构造函数则不保存。我编写了一些比较函数，它们的工作方式类似于标准 (==) 和 (/=) 运算符，但对于不这样做的比较返回 Nothing没有道理：

data Variant = IntValue Int
             | FloatValue Float
             | NoValue

equal :: Variant -> Variant -> Maybe Bool
equal (IntValue a) (IntValue b) = Just (a == b)
equal (FloatValue a) (FloatValue b) = Just (a == b)
equal _ _ = Nothing

unequal :: Variant -> Variant -> Maybe Bool
unequal (IntValue a) (IntValue b) = Just (a /= b)
unequal (FloatValue a) (FloatValue b) = Just (a /= b)
unequal _ _ = Nothing

这可行，但重复很笨拙 - 特别是因为我实际上有更多的 Variant 构造函数和更多的比较函数。

我认为我可以将重复分解为在比较函数上参数化的辅助函数：

helper :: (Eq a) => (a -> a -> Bool) -> Variant -> Variant -> Maybe Bool
helper f (IntValue a) (IntValue b) = Just (f a b)
helper f (FloatValue a) (FloatValue b) = Just (f a b)
helper _ _ _ = Nothing

equal' :: Variant -> Variant -> Maybe Bool
equal' = helper (==)

unequal' :: Variant -> Variant -> Maybe Bool
unequal' = helper (/=)

但这不起作用，因为类型变量 a 显然无法绑定到两个 Inthelper的定义中同时使用code>和Float； GHC 将其绑定到 Float，然后抱怨处理 IntValue 的行上的类型不匹配。

像 (==) 这样的函数直接使用时是多态的；有没有办法将它传递给另一个函数并让它保持多态？

Answer 1

是的，这是可能的，但仅限于 语言扩展：

{-# LANGUAGE Rank2Types #-}

helper :: (forall a. (Eq a) => (a -> a -> Bool))
       -> Variant -> Variant -> Maybe Bool
helper f (IntValue a) (IntValue b) = Just (f a b)
helper f (FloatValue a) (FloatValue b) = Just (f a b)
helper _ _ _ = Nothing

forall a. 的作用与听起来类似； a 在括号内普遍量化，在括号外则超出范围。这意味着 f 参数需要对作为 Eq 实例的所有类型 a 是多态的，这正是您想要的。

这里的扩展被称为“rank 2”，因为它允许在最外层范围内使用常规样式的多态性，以及此处示例中的多态参数。为了进一步嵌套，您需要扩展RankNTypes，它是相当自描述的。

顺便说一句，关于更高级别的多态类型 - 请记住 forall 实际上是将变量绑定到类型的；事实上，你可以认为它们的行为很像 lambda。当您将此类函数应用于具有具体类型的对象时，参数的类型将由 forall 隐式绑定以用于该用途。例如，如果您尝试使用其类型由该函数外部的内部 forall 绑定的值，就会出现这种情况；该值的类型超出了范围，这使得很难做任何明智的事情（正如您可能想象的那样）。