Flex (Spark) 中从外观到视图的数据绑定

Question

我对 Spark 中的 Flex 开发非常陌生，想要阐明构建组件的最佳方法。

我之前曾尝试使用绑定表达式来设置 ViewStack 的选定索引：

public class MyComponentView extends SkinnableComponent
{
    public var selectedIndex:int = 0;

}

<s:Skin ...>
    <mx:ViewStack selectedIndex="{hostComponent.selectedIndex}">
            ....
    </mx:ViewStack>
</s:Skin ...>

但是，此绑定表达式似乎不起作用，尽管如果我将该绑定表达式移至 as:Label，它确实会显示正确的数字。

为了使其正常工作，我更改了代码：

public class MyComponentView extends SkinnableComponent
{
    [SkinPart(required = "true")]
    public var myStack:ViewStack;

    private var _selectedIndex:int = 0;

    private var _indexChanged:Boolean;

    public function set selectedHistoryIndex(value:int):void
    {
        _selectedIndex = value;
        _indexChanged = true;
        invalidateProperties();
    }

    override protected function partAdded(partName:String, instance:Object):void
    {
        super.partAdded(partName, instance);

        switch (instance)
        {
            case myStack:
                _indexChanged = true;
                invalidateProperties();
                break;
        }
    }

    override protected function commitProperties():void
    {
        super.commitProperties();

        if (_indexChanged && myStack)
        {
            _indexChanged = false;
            myStack.selectedIndex = _selectedIndex;
        }
    }

}

<s:Skin ...>
    <mx:ViewStack id="myStack">
            ....
    </mx:ViewStack>
</s:Skin ...>

这是我打算这样做的方式吗？

Answer 1

对于我来说，你的第二种方法更可取。我宁愿更改一些代码以使其更好：

public function set selectedHistoryIndex(value:int):void
{
    if (_selectedIndex == value)
        return;
    _selectedIndex = value;
    _indexChanged = true;
    invalidateProperties();
}

是的，您可以从皮肤绑定到组件的属性，但是这样视图（Spark 架构中的皮肤用于 MVC 中的视图，主机组件用于 M 和 C）了解 M 的知识不太好。第一个实现需要来自皮肤的这些知识。

第二种实现使View成为真正的View（由M管理）。这很好。