如何编写维护本地状态的宏？

Question

这似乎有效，它是一个宏，根据扩展的次数扩展为连续的整数。

;; Library (test macro-state)
(library
 (test macro-state)
 (export get-count incr-count)
 (import (rnrs))

 (define *count* 0)
 (define (get-count) *count*)
 (define (incr-count) (set! *count* (+ *count* 1)))

 )

;; Program
(import (rnrs) (for (test macro-state) expand))

(define-syntax m
  (lambda (x)
    (syntax-case x ()
      ((m) (begin (incr-count) (datum->syntax #'m (get-count)))))))

(write (list (m) (m) (m)))
(newline)
;; prints (1 2 3)

但这对我来说很笨拙，因为宏状态 *count* 和宏 m 本身位于不同的模块中。在 r6rs 中是否有更好的方法来执行此操作，最好是不将实现拆分为两个模块的方法？

编辑

我应该明确指出，虽然这个示例只是一个宏，但实际上我正在寻找一种在多个宏需要共享状态时有效的方法。

Answer 1

您可以将状态设置为宏转换器的本地状态：

(define-syntax m
  (let ()
    (define *count* 0)
    (define (get-count) *count*)
    (define (incr-count) (set! *count* (+ *count* 1)))
    (lambda (x)
      (syntax-case x ()
        ((m) (begin (incr-count) (datum->syntax #'m (get-count))))))))

编辑添加：在Racket中，你也可以这样做：

(begin-for-syntax
  (define *count* 0)
  (define (get-count) *count*)
  (define (incr-count) (set! *count* (+ *count* 1))))
(define-syntax m
  (lambda (x)
    (syntax-case x ()
      ((m) (begin (incr-count) (datum->syntax #'m (get-count)))))))

但我不认为 R6RS 有任何与 begin-for-syntax 相对应的东西。