读取批处理文件中的标准输入流

Question

是否可以在批处理文件中使用管道标准输入流？

我希望能够将一个命令的输出重定向到我的批处理文件 process.bat 列表中，这样：

C:\>someOtherProgram.exe | process.bat

我的第一次尝试如下：

echo OFF
setlocal

:again
set /p inputLine=""
echo.%inputLine%
if not (%inputLine%)==() goto again

endlocal
:End

当我使用 type testFile.txt | 测试它时process.bat 它会重复打印第一行。

还有别的办法吗？

Answer 1

set /p 不适用于管道，它从输入中获取一行（随机）。
但是您可以在 for 循环内使用 more。

@echo off
setlocal
for /F "tokens=*" %%a in ('more') do (
  echo #%%a
)

但对于以分号开头的行会失败（因为 eol 的 FOR-LOOP 标准是 ;）。
并且它无法读取空行。
但是使用 findstr 你也可以解决这个问题，它在每行前面加上行号，所以你永远不会得到空行。
然后前缀被删除到第一个冒号。

@echo off
setlocal DisableDelayedExpansion

for /F "tokens=*" %%a in ('findstr /n "^"') do (
  set "line=%%a"
  setlocal EnableDelayedExpansion
  set "line=!line:*:=!"
  echo(!line!
  endlocal
)

或者，在某些不包含 findstr 的环境（例如 WinRE）上，使用 find.exe 替代方案可能就足够了。 find 将接受空搜索字符串 ""，并允许搜索反转。这将允许这样的事情：

@echo off
setlocal DisableDelayedExpansion

for /F "tokens=*" %%a in ('find /v ""') do (
  ...

Answer 2

set“line=!line:*:=!”语法为：

1. set 需要一个参数，即 a=b。
   如果 a 包含空格或其他内容，则必须使用该参数引起来的引号。在这里，我没有看到任何

2. !line:*:=!
   对于此语法，您可以输入“set /?”来查看有关使用变量的官方说明。
   !var! 类似于 %var%，用于获取值。但 !var! 表示延迟扩展。

行 var name

第一

：变量修饰标记。 **:= **:=（空），替换变量值中匹配的字符串“*:”（实际上从字符串开始到第一个： 发生）与（空），即删除从开始到第一个冒号的子字符串。

Answer 3

FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
    >  CON    ECHO.%%B
    >> %File% ECHO.%%B
)

来源：http://www.robvanderwoude.com/unixports.php#TEE

Answer 4

或者，在某些不包含 findstr 的环境（例如 WinRE）上，使用 find.exe 替代方案可能就足够了。 find 将接受空搜索字符串 ""，并允许搜索反转。这将允许这样的事情：

@echo off
setlocal DisableDelayedExpansion

for /F "tokens=*" %%a in ('find /v ""') do (
  set "line=%%a"
  echo(!line!
)