如何在 FORTRAN 例程中创建结构/数组的句柄？

Question

我需要在子例程中为相当复杂的结构创建一个句柄（此处替换为“real a(2)”），然后仅将句柄/指针传回主例程。我还需要能够创建尽可能多的所需结构。 问题是，一旦指针返回到 main，数据结构就会被释放。这是我的尝试：

  program main
  implicit none

  integer i, j
  real a(2) ! This can be a complicated structure

  a=(/1.1,2.2/)
  call myalloc(a,i)

  a=(/3.1,4.2/)
  call myalloc(a,j)

  call myprint(i)      
  call myprint(j)

  stop
  end

c------------------------------------------------

  subroutine myalloc(a,i)
  implicit none

  real, pointer :: i(:) ! If I add "save" attribute I will get an error
  real, target :: a(2)

  allocate(i(2))
  i => a

  return
  end 

c-------- ------------------------

  subroutine myprint (i)
  implicit none

  real, pointer :: i(:)

  print *, i

  return
  end

c------------------------- --------

结果是一些垃圾值： 3.93764868E-43 1.40129846E-45

或者我会得到： 在文件 test.f 的第 41 行（单位 = 6，文件 = 'stdout'） 内部错误：list_formatted_write()：类型错误

任何帮助将不胜感激。

Answer 1

这段代码有太多错误，几乎很难做出建设性的回答。

如果我理解你想要做什么，子例程 myalloc 应该像一个复制构造函数一样 - 将内存分配到提供的指针上，然后将初始化参数的内容复制到分配的内存上。所以 myalloc 中的关键错误是这两行：

  allocate(i(2))
  i => a

这里首先将内存分配给指针 i，然后分配 i 指向 a 。在这种情况下为什么要分配 i 呢？我认为这更接近您想要做的事情：

subroutine myalloc(a,b,n)
  implicit none

  real, dimension(n) :: a
  real, pointer,dimension(:) :: b
  integer :: n

  allocate(b(n))
  b = a ! This copies the contents of the array a to the allocation for b

  return
end 

然后在您的主程序中存在许多无法解释的事情。为什么i和j声明为整数？当然，它们必须是指向真实数组的指针，如果目的是将它们传递给您的 myalloc，对它们执行分配/复制操作，然后打印它们？如果是这种情况，那么将您的 main 更改为类似这样的内容应该更接近您想要做的事情：

program main
    implicit none

    interface
        subroutine myalloc(a,b,n)
        real,dimension(n) :: a
        real,pointer,dimension(:) :: b 
        integer :: n
        end subroutine myalloc

        subroutine myprint(i)
        real,pointer,dimension(:) :: i
        end subroutine myprint
    end interface

    real,pointer,dimension(:) :: i, j
    real :: a(2)

    a=(/1.1,2.2/)
    call myalloc(a,i,2)

    a=(/3.1,4.2/)
    call myalloc(a,j,2)

    call myprint(i)
    call myprint(j)

    stop
end

通过这些更改，您应该在运行时得到：

$ ./pointer
   1.100000       2.200000    
   3.100000       4.200000    

这更接近您期望的输出吗？