使用 Stata 进行聚合的 Fisher 精确检验

Question

我有一组如下数据：

A B C D
1 2 3 4
2 3 4 5

它们是聚合数据，ABCD构成2x2表，我需要对每一行进行Fisher精确检验，并为该行的Fisher精确检验的p值添加一个新列。

我可以使用fisher.exact和循环在R中执行此操作，但我在Stata中找不到用于Fisher精确测试的命令。

Answer 1

你用 R 术语思考，而这在 Stata 中通常是徒劳的（就像 Stata 人员不可能弄清楚如何在 R 中by ... : regress 一样；每个包都有它的自己的范式和自己的优势）。

没有要添加列的对象。也许您可以更多地说明您最终需要对 p 值做什么，以便找到您的 Stata 合作者会同情的合适解决方案。

如果您确实想添加一个新列（生成一个新变量，用 Stata 来说），那么您可能需要查看 tabulate 及其返回值：

    clear
    input x y f1 f2
    0 0 5 10
    0 1 7 12
    1 0 3 8
    1 1 9 5
    end

我假设您的ABC D 代表两个二元变量，数字是数据中的频率。您必须清除内存，因为 Stata 一次只考虑一个数据集。

然后，您可以制表结果并生成包含p值的新变量，尽管创建包含常量值的变量会浪费大量内存：

    tabulate x y [fw=f1], exact
    return list
    generate p1 = r(p_exact)
    tabulate x y [fw=f2], exact
    generate p2 = r(p_exact)

这里，< code>[fw=variable] 是指定频率权重的一种方式；我输入了 return list 来了解 Stata 将什么样的信息存储为过程结果。 这就是 Stata 所使用的类似对象的东西。 R 将在 fisher.test()$p.value 组件中返回测试结果，Stata 创建返回值，r(component) 用于简单命令，e(component) 用于估计命令。

如果你想要一个循环解决方案（如果你有很多集合），你可以这样做：

   forvalues k=1/2 {
    tabulate x y [fw=f`k'], exact
    generate p`k' = r(p_exact)
   }

恕我直言，这就是 Stata 的脚本编写能力，比 R 强得多（尽管可以说这是一个极其肮脏的编程技巧）。本地宏 k 的取值范围为 1 到 2，并且该宏在大括号内的代码段中的任何位置都被替换为“k”。

或者，您可以将结果作为标量保存在 Stata 短期内存中：

    tabulate x y [fw=f1], exact
    scalar p1 = r(p_exact)
    tabulate x y [fw=f2], exact
    scalar p2 = r(p_exact)

但是，标量与数据集无关，因此您无法使用
数据。

像cci这样的直接命令建议here 也会返回您可以类似检索的值。

HTH、斯塔斯

Answer 2

看一下带有 exact 选项的 cci 命令：

cci 10 15 30 10, exact

它是所谓的“立即”命令的一部分。它们允许您直接根据参数而不是根据存储在内存中的数据进行计算。查看立即帮助

Answer 3

发帖者原始问题中的每个观察结果显然都由一个传统 2 x 2 表中的四个计数组成。斯塔斯代码适用于个人观察数据。 Nick指出-cci-可以分析abcd数据。下面的代码将 -cci 应用于每个表，并且与 Stas 的代码一样，将 p 值添加到数据集。 forvalues i = 1/`=_N' 语句告诉 Stata 从第一个观察到最后一个观察运行循环。 a[`i'] 指的是第 i 个观察中变量“a”的值。

    clear
    input a b c d
    10 2 8 4
    5 8 2 1
    end

    gen exactp1 = .
    gen exactp2 =.
    label var exactp1 "1-sided exact p"
    label var exactp2 "2-sided exact p"
    forvalues i = 1/`=_N'{
      local a = a[`i']
      local b = b[`i']
      local c = c[`i']
      local d = d[`i']
      qui cci `a' `b' `c' `d', exact
      replace exactp1 = r(p1_exact) in `i'
      replace exactp2 = r(p_exact) in `i'
      }
    list

请注意，为局部宏指定与变量相同的名称是没有问题的。