如何使用 Perl 列出 ZIP 文件的内容？

Question

我的目标就是标题中所说的。

我有以下代码行，它只是打印出 [view archive] ，当我单击它时，浏览器只会下载 zip 文件。

print "\<a href=\"http:\/\/intranet.domain.com\/~devcvs\/view-file.cgi?file=$reviewdata{'document'}&review_id=$reviewdata{'id'}\"\>[view archive]\<\/a\>\n";

我想做的是在页面上的任何位置列出此 zip 文件中包含的文件，例如在该链接链接到的下面甚至新页面上，并将文件名作为参数。

我相信一旦完成此操作，浏览器就应该处理剩下的事情，只需单击这些文件并在浏览器中查看它们，因为它们将是 pdf 和 html 文件，我预计不会有任何问题。

我确信有一个模块可以做到这一点，但我不确定如何使用它来实现我的目标。

非常感谢任何帮助。

Answer 1

看一下 Archive::Zip ：

use strict;
use warnings;

use Archive::Zip qw/ :ERROR_CODES :CONSTANTS /;

my $zipFile = 'someZip.zip';

my $zip = Archive::Zip->new();

unless ( $zip->read( $zipFile ) == AZ_OK ) {  # Make sure archive got read

    die 'read error';
}

my @files = $zip->memberNames();  # Lists all members in archive

print $_, "\n" for @files;

Answer 2

使用 Archive::Zip 肯定会让代码变得更简单，如果您要广泛处理 zip 文件，您可能应该安装该模块。

然而，对于那些不想安装任何东西的人来说，有一种方法可以仅使用核心模块 IO::Uncompress::Unzip 来列出 zip 文件的内容（已经是任何标准 Perl 发行版的一部分） ）。

use strict;
use warnings;

use IO::Uncompress::Unzip qw($UnzipError);

my $zipFile = '/path/to/zipfile.zip';

my $u = IO::Uncompress::Unzip->new($zipFile)
    or die "Error: $UnzipError\n";

my $status;
for ($status = 1; $status > 0; $status = $u->nextStream()) {
    my $header = $u->getHeaderInfo();
    my $zippedFile = $header->{Name};
    if ($zippedFile =~ /\/$/) {
        last if $status < 0;
        next;
    }
    print "$zippedFile\n";
}