Tcl 中有获取连续数字数组的简写吗？

Question

例如，在 Perl 中，要获取从 1 到 10 的数字的顺序数组，您可以简单地执行以下操作：

@myArray = (1 .. 10);

这两个句点用作此操作的简写，而不是创建 for 循环或手动写出整个内容。我使用过的其他语言也有类似的东西。

Tcl 中是否存在类似的简写？

Answer 1

您可以定义该方法：

proc fillArray {a b} {
    eval return \[list $a [string repeat "\[incr a\] " [incr b -$a]]\]
}

并将其用作：

set myArray [fillArray 1 10]

---

您甚至可以美化过程的调用，使其看起来像在 perl 中一样。为此，只需重新定义 unknown 过程：

rename unknown __unknown
proc unknown {args} {
  if {[llength $args] == 3} {
    lassign $args a op b
    if {[string is integer $a] && $op == ".." && [string is integer $b]} {
      return [fillArray $a $b]
    }
  }
  return [uplevel __unknown {*}$args]
}

之后您可以简单地编写为：

set myArray [1 .. 10]

:)

Answer 2

不完全是这个，但

% package require struct::list
1.6.1
% struct::list iota 10
0 1 2 3 4 5 6 7 8 9

也可以在 this 中搜索“iota”关键字，看看如何使用一行。

Answer 3

除了表达式（它们自己的小语言）之外，Tcl 没有运算符，并且始终是严格前缀驱动的语言。这意味着没有这样方便的循环简写。另一方面，Tcl 的标准命令没有什么特别之处（除了一些在这里无关紧要的小效率细节），因此制作自己的命令没有问题：

proc .. {from to} {
    if {$from >= $to} {
        for {set i $from} {$i <= $to} {incr i}    {lappend out $i}
    } else {
        for {set i $from} {$i >= $to} {incr i -1} {lappend out $i}
    }
    return $out
}

puts [.. 1 10];   # --> “1 2 3 4 5 6 7 8 9 10”

您可以通过使用未知处理程序来伪造中缀运算符（如 GrAnd 的回答） ）但是与上面相比，这确实相当慢。

Answer 4

不，tcl 中不存在类似的简写。

如果您确实想要速记，您可以创建自己的看起来几乎相同的命令。例如：

proc : {start ignore end} {
    set result []
    for {set i $start} {$i <= $end} {incr i} {
        lappend result $i
    }
    return $result
}

puts "from 1 to 10: [: 1 .. 10]"