使用node.js和lazy时了解EOF

Question

我有一个用 CoffeeScript 编写的例程，在 node.js 中运行，从 Jade 文件中读取行。它看起来像这样：

each_line = (file, callback) ->
  last_line = null

  lazy = Lazy(fs.createReadStream(file)).lines.map(String).filter (line) -> 
    not (
      # Filter the not interesting rows in the top of the file
      /^html$/i.test(line) or 
      /^\s+body$/i.test(line) or 
      /^\s+\/\/\s+Generator.*$/i.test(line)
      )

  lazy.forEach (line) ->
    # We only emit those lines that are whole lines, multilines will become joined
    if /^\t/g.test(line)
      last_line += line.replace(/\t/g, '').replace(/(\r\n|\n|\r)/gm," ")
    else
      callback(last_line) if last_line
      last_line = line.replace(/(\r\n|\n|\r)/gm," ")

由于所有这些都是异步运行的，所以我需要知道 EOF，以便我可以在整个迭代完成后执行操作。有人有什么建议吗？

Answer 1

我会先说我自己没有使用过 Lazy，但我只是看了文档。

我有点期待 Lazy 发出“结束”事件，但我无法判断是否会发出“结束”事件，无论哪种方式，您都可以将回调直接绑定到读取流上的结束事件。

each_line = (file, callback, eof_callback) ->
  last_line = null

  stream = fs.createReadStream file

  stream.on 'end', eof_callback

  lazy = Lazy(stream).lines.map(String).filter (line) -> 
    not (
      # Filter the not interesting rows in the top of the file
      /^html$/i.test(line) or 
      /^\s+body$/i.test(line) or 
      /^\s+\/\/\s+Generator.*$/i.test(line)
      )

  lazy.forEach (line) ->
    # We only emit those lines that are whole lines, multilines will become joined
    if /^\t/g.test(line)
      last_line += line.replace(/\t/g, '').replace(/(\r\n|\n|\r)/gm," ")
    else
      callback(last_line) if last_line
      last_line = line.replace(/(\r\n|\n|\r)/gm," ")

Answer 2

我相信 Lazy 会在创建的原始 Lazy 对象上发出“结束”事件：

Lazy = require('lazy')
fs = require('fs')

readLines = (filename, next) ->
  lazy = new Lazy(fs.createReadStream(filename))
  lazy.on 'end', ->
    if next then next null
  lazy.lines.forEach (line) ->
    console.log 'Read line:', line.toString()

readLines process.argv[1], ->
  console.log 'All done.'