Emacs：.emacs 中延迟加载模式的最佳实践？

Question

遇到相关文件扩展名时，是否有关于延迟加载模式的最佳实践？

此时我已经安装了大约 25 种不同的 Emacs 模式，并且启动变得很慢。例如，虽然准备好 clojure 模式很好，但我很少使用它，并且我想完全避免加载它，除非我打开扩展名为 .clj 的文件。这种“惰性需求”功能似乎是一般模式配置的正确方法。

我在网上找不到任何东西，所以我自己尝试了一下。

而不是：

(require 'clojure-mode)
(require 'tpl-mode) 

我有这个：

(defun lazy-require (ext mode)
  (add-hook
   'find-file-hook
   `(lambda ()
      (when (and (stringp buffer-file-name)
                 (string-match (concat "\\." ,ext "\\'") buffer-file-name))
        (require (quote ,mode))
        (,mode)))))

(lazy-require "soy" 'soy-mode)
(lazy-require "tpl" 'tpl-mode)

这似乎有效（我是一个 elisp 新手，所以欢迎评论！），但我对在网上找不到任何关于这个主题的文章感到不安。这是一个合理的做法吗？

Answer 1

您想要的工具称为自动加载。 clojure-mode 源文件 clojure-mode.el 包含评论如何安排：

;;     Add these lines to your .emacs:
;;       (autoload 'clojure-mode "clojure-mode" "A major mode for Clojure" t)
;;       (add-to-list 'auto-mode-alist '("\\.clj$" . clojure-mode))

Answer 2

这是一种方式，

(provide 'my-slime)
(eval-after-load "slime"
  '(progn
     (setq slime-lisp-implementations
           '((sbcl ("/usr/bin/sbcl"))
             (clisp ("/usr/bin/clisp")))
           common-lisp-hyperspec-root "/home/sujoy/documents/hyperspec/")
     (slime-setup '(slime-asdf
                    slime-autodoc
                    slime-editing-commands
                    slime-fancy-inspector
                    slime-fontifying-fu
                    slime-fuzzy
                    slime-indentation
                    slime-mdot-fu
                    slime-package-fu
                    slime-references
                    slime-repl
                    slime-sbcl-exts
                    slime-scratch
                    slime-xref-browser))
     (slime-autodoc-mode)
     (setq slime-complete-symbol*-fancy t)
     (setq slime-complete-symbol-function 'slime-fuzzy-complete-symbol)
(add-hook 'lisp-mode-hook (lambda () (slime-mode t)))))

(require 'slime)

同时，

;; slime mode
(autoload 'slime "my-slime" "Slime mode." t)
(autoload 'slime-connect "my-slime" "Slime mode." t)