从文件读取数字到变量 (Perl)

Question

我一直在尝试编写一个程序来将文本格式的数字列读入 Perl 变量中。

基本上，我有一个包含描述和数字的文件：

ref   5.25676      0.526231      6.325135
ref   1.76234     12.62341       9.1612345

等等。

我想将数字放入具有不同名称的变量中，例如

ref_1_x=5.25676
ref_1_y=0.526231

等。

这是我到目前为止所得到的：

print "Loading file ...";
open (FILE, "somefile.txt");
@text=<FILE>;
close FILE;
print "Done!\n";
my $count=0;
foreach $line (@text){
    @coord[$count]=split(/ +/, $line);
}

我正在尝试比较中写入的位置相互文件，因此在此之后需要另一个循环。

Answer 1

抱歉，您不太清楚您要做什么以及“ref”指的是什么。如果我误解了您的问题，请赞扬并澄清。

---

首先，我强烈建议不要使用变量名称来构造数据（例如使用$ref_1_x来存储带有标签“ref”的第一行的x坐标）。

如果您想存储 x、y 和 z 坐标，您可以将其作为 3 个元素的数组来执行，与您所做的非常相似 - 唯一的区别是您想要存储一个数组引用（您无法将数组作为值存储在 Perl 中的另一个数组中）：

my ($first_column, @data) = split(/ +/, $line); # Remove first "ref" column
@coordinates[$count++] = \@data; # Store the reference to coordinate array

然后，要访问第 2 行的 x 坐标，您可以执行以下操作：

$coordinates[1]->[0]; # index 1 for row 2; then sub-index 0 for x coordinate.

---

如果您坚持将 3 个坐标存储在命名数据结构中，因为 子索引0 表示 x 坐标 看起来可读性较差 -一般来说，这是一个有效的问题，但对于 3 列来说并不是真正的问题 - 使用散列而不是数组：

my ($first_column, @data) = split(/ +/, $line); # Remove first "ref" column
@coordinates[$count++] = { x => $data[0], y => $data[1], z => $data[2] };
# curly braces - {} - to store hash reference again

然后，要访问第 2 行的 x 坐标，您可以：

$coordinates[1]->{x}; # index 1 for row 2

---

现在，如果您还想存储具有在单独的“ref”标记数据结构中的第一列值“ref”，您可以通过将原始 @coordinates 数组包装为具有“ref”键的散列中的值来实现这一点。

my ($label, @data) = split(/ +/, $line); # Save first "ref" label
$coordinates{$label} ||= []; # Assign an empty array ref 
                          #if we did not create the array for a given label yet.
push @{ $coordinates{$label} }, { x => $data[0], y => $data[1], z => $data[2] };
# Since we don't want to bother counting per individual label, 
# Simply push the coordinate hash at the end of appropriate array.
# Since coordinate array is stored as an array reference, 
# we must dereference for push() to work using @{ MY_ARRAY_REF } syntax

然后，要访问标签“ref”第 2 行的 x 坐标，您可以执行以下操作：

$label = "ref";
$coordinates{$label}->[1]->{x}; # index 1 for row 2 for $label

另外，您的原始示例代码有一些过时的习惯用法，您可能希望以更好的风格编写它们（使用 3 参数形式的 open()，检查 IO 操作上的错误，例如 open()；使用词法文件句柄；将整个文件存储在一个大数组中，而不是逐行读取）。

这是一个稍作修改的版本：

use strict;
my %coordinates;
print "Loading file ...";
open (my $file, "<", "somefile.txt") || die "Can't read file somefile.txt: $!";
while (<$file>) {
    chomp;
    my ($label, @data) = split(/ +/); # Splitting $_ where while puts next line
    $coordinates{$label} ||= []; # Assign empty array ref if not yet assigned
    push @{ $coordinates{$label} }
       , { x => $data[0], y => $data[1], z => $data[2] };
}
close($file);
print "Done!\n";

---

尚不清楚您想要与什么进行比较，因此在没有进一步说明的情况下无法就此提供建议。

Answer 2

问题是您可能需要一个双数组（或散列或...）。而不是这样：

@coord[$count]=split(/ +/, $line);

使用：

@coord[$count++]=[split(/ +/, $line)];

将拆分的整个结果放入子数组中。因此，

print $coord[0][1];

应该输出“5.25676”。